blob: 15aa0dfbf8e83ea64e75caae6feec370bce94cd8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.4.2.ebuild,v 1.1 2012/05/19 21:31:31 tetromino Exp $
EAPI="4"
GCONF_DEBUG="yes"
inherit autotools eutils gnome2 pax-utils versionator virtualx
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="GNOME webbrowser based on Webkit"
HOMEPAGE="http://projects.gnome.org/epiphany/"
LICENSE="GPL-2"
SLOT="0"
IUSE="avahi doc +introspection +jit +nss test"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
# XXX: Should we add seed support? Seed seems to be unmaintained now.
RDEPEND="
>=dev-libs/glib-2.31.2:2
>=x11-libs/gtk+-3.3.14:3[introspection?]
>=dev-libs/libxml2-2.6.12:2
>=dev-libs/libxslt-1.1.7
>=app-text/iso-codes-0.35
>=net-libs/webkit-gtk-1.7.92:3[introspection?]
>=net-libs/libsoup-gnome-2.37.1:2.4
>=gnome-base/gnome-keyring-2.26.0
>=gnome-base/gsettings-desktop-schemas-0.0.1
>=x11-libs/libnotify-0.5.1
dev-db/sqlite:3
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-themes/gnome-icon-theme
x11-themes/gnome-icon-theme-symbolic
avahi? ( >=net-dns/avahi-0.6.22 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
!jit? ( net-libs/webkit-gtk[-jit] )
nss? ( dev-libs/nss )"
# paxctl needed for bug #407085
DEPEND="${RDEPEND}
app-text/gnome-doc-utils
>=dev-util/intltool-0.40
sys-devel/gettext
virtual/pkgconfig
jit? ( sys-apps/paxctl )
doc? ( >=dev-util/gtk-doc-1 )"
pkg_setup() {
DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
G2CONF="${G2CONF}
--enable-shared
--disable-schemas-compile
--disable-scrollkeeper
--disable-static
--with-distributor-name=Gentoo
$(use_enable avahi zeroconf)
$(use_enable introspection)
$(use_enable nss)
$(use_enable test tests)"
}
src_prepare() {
# Build-time segfaults under PaX with USE=introspection when building
# against webkit-gtk[introspection,jit]
if use introspection && use jit; then
epatch "${FILESDIR}/${PN}-3.3.90-paxctl-introspection.patch"
cp "${FILESDIR}/paxctl.sh" "${S}/" || die
eautoreconf
fi
gnome2_src_prepare
}
src_compile() {
# needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
unset DISPLAY
gnome2_src_compile
}
src_test() {
# FIXME: this should be handled at eclass level
"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
}
src_install() {
gnome2_src_install
use jit && pax-mark m "${ED}usr/bin/epiphany"
}
|
GitWeb