sci-electronics/qelectrotech/qelectrotech-0.30.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/qelectrotech/qelectrotech-0.30.ebuild,v 1.1 2013/12/22 16:56:39 pesa Exp $

EAPI=5
PLOCALES="cs de el en es fr it pl pt ro ru"

inherit l10n qt4-r2

MY_P=${PN}-${PV%0}-src

DESCRIPTION="Qt4 application to design electric diagrams"
HOMEPAGE="http://qelectrotech.org/"
SRC_URI="http://download.tuxfamily.org/qet/tags/20130928/${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="doc"

RDEPEND="
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	dev-qt/qtsql:4[sqlite]
	dev-qt/qtsvg:4
"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
"

S=${WORKDIR}/${MY_P}

DOCS=(CREDIT ChangeLog README)
PATCHES=(
	"${FILESDIR}/${PN}-0.3-fix-paths.patch"
)

qet_disable_translation() {
	sed -i -e "/TRANSLATIONS +=/s: lang/qet_${1}.ts::" ${PN}.pro || die
}

src_prepare() {
	qt4-r2_src_prepare
	l10n_for_each_disabled_locale_do qet_disable_translation
}

src_install() {
	qt4-r2_src_install

	if use doc; then
		doxygen Doxyfile || die
		dohtml -r doc/html/*
	fi
}