media-tv/freevo/freevo-1.4_rc2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/freevo/freevo-1.4_rc2.ebuild,v 1.1 2003/11/03 17:24:58 max Exp $

DESCRIPTION="Digital video jukebox (PVR, DVR)."
HOMEPAGE="http://www.freevo.org/"
SRC_URI="mirror://sourceforge/${PN}/${P/_/}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="matrox dvd encode lirc X"

DEPEND=">=dev-python/pygame-1.5.6
	>=dev-python/Imaging-1.1.3
	>=dev-python/pyxml-0.8.2
	>=dev-python/twisted-1.0.7
	>=dev-python/mmpython-0.3
	>=media-video/mplayer-0.92
	>=media-libs/freetype-2.1.4
	>=media-libs/libsdl-1.2.5
	>=media-tv/xmltv-0.5.19
	>=sys-apps/sed-4
	dvd? ( >=media-video/xine-ui-0.9.22 )
	encode? ( >=media-sound/cdparanoia-3.9.8 >=media-sound/lame-3.93.1 )
	matrox? ( >=media-video/matroxset-0.3 )
	lirc? ( app-misc/lirc >=dev-python/pylirc-0.0.3 )
	X? ( virtual/x11 )"

S="${WORKDIR}/${P/_/}"

inherit distutils

src_compile() {
	local myconf

	if [ "`/bin/ls -l /etc/localtime | grep Europe`" ] ; then
		myconf="$myconf --tv=pal"
	fi
	if [ "`use matrox`" ] ; then
		myconf="--geometry=768x576 --display=mga"
	elif [ "`use X`" ] ; then
		myconf="--geometry=800x600 --display=x11"
	else
		myconf="--geometry=800x600 --display=fbdev"
	fi

	sed -e "s:/etc/freevo/freevo.conf:${T}/freevo.conf:" \
		-i "${S}/src/setup_freevo.py" || die "sed failed"

	"${S}/freevo" setup ${myconf} || die "configure problem"

	sed -e "s:${T}/freevo.conf:/etc/freevo/freevo.conf:" \
		-i "${S}/src/setup_freevo.py" || die "sed failed"
}

src_install() {
	distutils_src_install

	insinto /etc/freevo
	doins "${T}/freevo.conf"
	newins local_conf.py.example local_conf.py

	exeinto /etc/init.d
	newexe "${FILESDIR}/freevo.rc6" freevo
	insinto /etc/conf.d
	newins "${FILESDIR}/freevo.conf" freevo

	if [ ! "`use lirc`" ] ; then
		dosed '/need lirc/d' /etc/init.d/freevo
	fi
	if [ ! "`use X`" ] ; then
		dosed '/need xfs/d' /etc/init.d/freevo
	fi

	rm -rf "${D}/usr/share/doc"
	newdoc Docs/README README.docs
	dodoc BUGS COPYING ChangeLog FAQ INSTALL PKG-INFO README TODO \
		Docs/{CREDITS,NOTES,plugins/*.txt}
	cp -r Docs/{installation,plugin_writing} "${D}/usr/share/doc/${PF}"
}

pkg_postinst() {
	einfo "Please check /etc/freevo/freevo.conf and"
	einfo "/etc/freevo/local_conf.py before starting Freevo."
	einfo "To rebuild freevo.conf with different parameters,"
	einfo "please run:"
	einfo "    freevo setup"
	echo

	if [ -e "/opt/freevo" ] ; then
		ewarn "Please remove /opt/freevo because it is no longer used."
	fi
	if [ -e "/etc/freevo/freevo_config.py" ] ; then
		ewarn "Please remove /etc/freevo/freevo_config.py."
	fi
	if [ -e "/etc/init.d/freevo-record" ] ; then
		ewarn "Please remove /etc/init.d/freevo-record"
	fi
	if [ -e "/etc/init.d/freevo-web" ] ; then
		ewarn "Please remove /etc/init.d/freevo-web"
	fi
}