media-sound/prokyon3/prokyon3-0.9.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/prokyon3/prokyon3-0.9.2.ebuild,v 1.9 2005/07/13 13:50:51 swegener Exp $

inherit eutils

DESCRIPTION="Multithreaded MP3 manager and tag editor based on Qt and MySQL"
HOMEPAGE="http://prokyon3.sourceforge.net"
SRC_URI="mirror://sourceforge/prokyon3/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 sparc amd64"
IUSE="ogg"

RESTRICT="primaryuri"

DEPEND="=x11-libs/qt-3*
	dev-db/mysql
	>=media-libs/id3lib-3.8.2
	ogg? ( >=media-libs/libogg-1.0
		>=media-libs/libvorbis-1.0 )"

pkg_setup() {
	if has_version x11-libs/qt && ! built_with_use x11-libs/qt mysql ; then
		eerror "You have installed Qt without MySQL support."
		eerror "Please make sure "mysql" is in your USE variable"
		eerror "and reemerge Qt"
		die "MySQL support for Qt not found"
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}

	# do not assume that $x_libraries is not empty
	epatch "${FILESDIR}/${P}-configure.patch"
}

src_compile() {
	econf \
		$(use_with ogg) \
		|| die "configure failed"

	emake || die "make failed"
}

src_install () {
	einstall || die "make install failed"
	dodoc ChangeLog INSTALL NEWS README
}