games-board/gnushogi/gnushogi-1.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/gnushogi/gnushogi-1.3.ebuild,v 1.12 2006/04/03 16:34:14 tupone Exp $

inherit eutils games

DESCRIPTION="Japanese version of chess (commandline + X-Version)"
HOMEPAGE="http://www.gnu.org/directory/games/gnushogi.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ppc ~amd64"
IUSE="X"

RDEPEND="virtual/libc
	sys-libs/ncurses
	X? ( || ( x11-libs/libXaw virtual/x11 ) )"
DEPEND="${RDEPEND}
	>=sys-devel/bison-1.34
	>=sys-devel/flex-2.5
	>=sys-apps/sed-4"

src_unpack() {
	local f

	unpack ${A}
	cd ${S}
	for f in `grep -Rl -- -ltermcap *` ; do
		einfo "Fixing ${f}"
		sed -i \
			-e 's:-ltermcap:-lcurses:' ${f} \
				|| die "sed ${f} failed"
	done
	epatch "${FILESDIR}/${PV}-errno.patch" \
		"${FILESDIR}/${P}"-gcc4.patch
}

src_compile() {
	egamesconf \
		$(use_with X x) \
		$(use_with X xshogi) || die
	addpredict /usr/games/lib/gnushogi/gnushogi.hsh
	emake || die "emake failed"
}

src_install() {
	dogamesbin gnushogi/gnushogi      || die "dogamesbin failed"
	if use X ; then
		dogamesbin xshogi/xshogi      || die "dogamesbin failed (X)"
	fi
	dogameslib gnushogi/gnushogi.bbk  || die "dogameslib failed"
	dodoc README NEWS CONTRIB
	prepgamesdirs
}