games-arcade/gav/gav-0.7.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/gav/gav-0.7.3.ebuild,v 1.5 2004/06/24 22:05:20 agriffis Exp $

inherit games

DESCRIPTION="GPL Arcade Volleyball"
HOMEPAGE="http://gav.sourceforge.net"
# the themes are behind a lame php-counter script.
SRC_URI="mirror://sourceforge/gav/${P}.tar.gz
	mirror://gentoo/fabeach.tgz
	mirror://gentoo/florindo.tgz
	mirror://gentoo/inverted.tgz
	mirror://gentoo/naive.tgz
	mirror://gentoo/unnamed.tgz
	mirror://gentoo/yisus.tgz
	mirror://gentoo/yisus2.tgz"

KEYWORDS="x86"
LICENSE="GPL-2"
SLOT="0"

RDEPEND="media-libs/sdl-image
	media-libs/sdl-net
	media-libs/libsdl"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

IUSE=""

src_unpack() {
	unpack ${P}.tar.gz
	cd ${S}

	cp Makefile.Linux Makefile               || die "cp 1 failed"
	cp automa/Makefile.Linux automa/Makefile || die "cp 2 failed"
	cp menu/Makefile.Linux menu/Makefile     || die "cp 3 failed"
	cp net/Makefile.Linux net/Makefile       || die "cp 4 failed"

	sed -i \
		-e "s:/usr/bin:${GAMES_BINDIR}:" Makefile || \
			die "sed Makefile failed"
	sed -i \
		-e "/-Wall/ s$ ${CXXFLAGS}" CommonHeader || \
			die "sed CommonHeader failed"

	# Now, unpack the additional themes
	cd ${S}/themes
	# unpack everything because it's easy
	unpack ${A}
	# and kill off what we don't want
	rm -rf ${P}

	# no reason to have executable files in the themes
	find . -type f -exec chmod a-x \{\} \;
}

src_compile() {
	egamesconf || die
	# bug #41530 - doesn't like the hot parallel make action.
	emake -j1 || die "emake failed"
}

src_install() {
	dodir ${GAMES_BINDIR}   || die "dodir failed"
	egamesinstall ROOT=${D} || die
	dodoc CHANGELOG README  || die "dodoc failed"
	prepgamesdirs
}