1 files changed, 50 insertions, 0 deletions
diff --git a/sci-libs/indilib/indilib-0.9.6.ebuild b/sci-libs/indilib/indilib-0.9.6.ebuild
new file mode 100644
index 000000000000..fd75e20f1a76
--- /dev/null
+++ b/sci-libs/indilib/indilib-0.9.6.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/indilib/indilib-0.9.6.ebuild,v 1.1 2013/01/09 12:25:21 kensington Exp $
+
+EAPI=5
+
+MY_PN="lib${PN/lib/}"
+
+inherit base cmake-utils
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="http://indi.sourceforge.net/index.php/Main_Page"
+SRC_URI="mirror://sourceforge/${PN/lib/}/${MY_PN}_${PV}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="nova v4l"
+
+RDEPEND="
+	>=sci-libs/cfitsio-3.140
+	sys-libs/zlib
+	virtual/libusb:0
+	nova? ( >=sci-libs/libnova-0.12.1 )
+"
+DEPEND="${RDEPEND}
+	v4l? ( >=sys-kernel/linux-headers-2.6 )
+"
+
+DOCS=( AUTHORS ChangeLog README README.drivers TODO )
+
+PATCHES=(
+	"${FILESDIR}/0.9.1-fix_symlinks.patch"
+)
+
+S=${WORKDIR}/${MY_PN}-${PV}
+
+src_prepare() {
+	base_src_prepare
+
+	sed -e "s|/etc/udev/rules.d|/lib/udev/rules.d|" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with nova)
+	)
+	cmake-utils_src_configure
+}