1 files changed, 62 insertions, 0 deletions
diff --git a/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.14.3.ebuild b/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.14.3.ebuild
new file mode 100644
index 000000000000..c87c9a919ab4
--- /dev/null
+++ b/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.14.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdebase-kioslaves/kdebase-kioslaves-4.14.3.ebuild,v 1.1 2014/11/16 12:21:27 alexxy Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-runtime"
+KMMODULE="kioslave"
+inherit kde4-meta
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+DESCRIPTION="kioslave: the kde VFS framework - kioslave plugins present a filesystem-like view of arbitrary data"
+IUSE="+bzip2 exif debug lzma minimal openexr samba +sftp"
+
+# tests hang, last checked for 4.2.96
+RESTRICT="test"
+
+DEPEND="
+	virtual/jpeg:0
+	!aqua? ( x11-libs/libXcursor )
+	bzip2? ( app-arch/bzip2 )
+	exif? ( media-gfx/exiv2:= )
+	openexr? ( media-libs/openexr:= )
+	samba? ( || ( <net-fs/samba-4.0.0_alpha1[smbclient] >=net-fs/samba-4.0.0_alpha1[client] ) )
+	sftp? ( >=net-libs/libssh-0.4.0:=[sftp] )
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kdelibs 'bzip2?,lzma?')
+	$(add_kdebase_dep kdialog)
+	virtual/ssh
+	!aqua? ( !kernel_SunOS? ( virtual/eject ) )
+"
+
+KMEXTRA="
+	kioexec
+	kdeeject
+"
+
+PATCHES=( "${FILESDIR}/${PN}-CVE-2014-8600.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_SLP=OFF
+		$(cmake-utils_use_with bzip2 BZip2)
+		$(cmake-utils_use_with exif Exiv2)
+		$(cmake-utils_use_with lzma LibLZMA)
+		$(cmake-utils_use_with openexr OpenEXR)
+		$(cmake-utils_use_with samba)
+		$(cmake-utils_use_with sftp LibSSH)
+	)
+	kde4-meta_src_configure
+}
+
+src_install() {
+	kde4-meta_src_install
+
+	if use minimal; then
+		rm "${D}"/usr/lib64/libmolletnetwork.so "${D}"/usr/share/config.kcfg/jpegcreatorsettings.kcfg
+		rmdir "${D}"/usr/share/config.kcfg/
+	fi
+}