1 files changed, 43 insertions, 0 deletions
diff --git a/dev-ruby/actionmailer/actionmailer-3.0.12.ebuild b/dev-ruby/actionmailer/actionmailer-3.0.12.ebuild
new file mode 100644
index 000000000000..588e5056300e
--- /dev/null
+++ b/dev-ruby/actionmailer/actionmailer-3.0.12.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionmailer/actionmailer-3.0.12.ebuild,v 1.1 2012/04/04 09:47:56 graaff Exp $
+
+EAPI=4
+USE_RUBY="ruby18 ree18"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="actionmailer.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Framework for designing email-service layers"
+HOMEPAGE="http://rubyforge.org/projects/actionmailer/"
+SRC_URI="http://github.com/rails/rails/tarball/v${PV} -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="3.0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RUBY_S="rails-rails-*/actionmailer"
+
+ruby_add_rdepend "~dev-ruby/actionpack-${PV}
+	>=dev-ruby/mail-2.2.19"
+ruby_add_bdepend "test? (
+	>=dev-ruby/mocha-0.9.5
+	virtual/ruby-test-unit
+)"
+
+all_ruby_prepare() {
+	# Set test environment to our hand.
+	rm "${S}/../Gemfile" || die "Unable to remove Gemfile"
+	sed -i -e '/\/load_paths/d' test/abstract_unit.rb || die "Unable to remove load paths"
+
+	sed -i -e '/dependency.*mail/s:~>:>=:' "${RUBY_FAKEGEM_GEMSPEC}" || die
+
+	# Rename private method to avoid conflict with the simple_format
+	# TextHelper. Already fixed in Rails 3.1.
+	sed -i -e 's/simple_format/format_paragraph/' lib/action_mailer/mail_helper.rb || die
+}