1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/pycups/pycups-1.9.61-r1.ebuild b/dev-python/pycups/pycups-1.9.61-r1.ebuild
new file mode 100644
index 000000000000..5bf9b69d39ce
--- /dev/null
+++ b/dev-python/pycups/pycups-1.9.61-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycups/pycups-1.9.61-r1.ebuild,v 1.1 2012/07/31 08:09:49 dilfridge Exp $
+
+EAPI="3"
+
+PYTHON_DEPEND="2:2.5"
+RESTRICT_PYTHON_ABIS="*-jython"
+inherit eutils distutils flag-o-matic
+
+DESCRIPTION="Python bindings for the CUPS API"
+HOMEPAGE="http://cyberelk.net/tim/data/pycups/"
+SRC_URI="http://cyberelk.net/tim/data/pycups/${P}.tar.bz2 http://dev.gentoo.org/~dilfridge/distfiles/${P}-cups16.patch.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+SLOT="0"
+IUSE="doc examples"
+
+RDEPEND="
+	net-print/cups
+"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/epydoc )
+"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	epatch "${WORKDIR}/${P}-cups16.patch"
+	distutils_src_prepare
+}
+
+src_compile() {
+	append-cflags -DVERSION=\\\"${PV}\\\"
+	distutils_src_compile
+
+	if use doc; then
+		emake doc || die "emake doc failed"
+	fi
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		dohtml -r html/ || die "installing html docs failed"
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/"${P}"
+		doins -r examples/ || die "installing examples failed"
+	fi
+}