1 files changed, 72 insertions, 0 deletions
diff --git a/dev-java/maven-bin/maven-bin-3.1.0.ebuild b/dev-java/maven-bin/maven-bin-3.1.0.ebuild
new file mode 100644
index 000000000000..4e98e25cd5b1
--- /dev/null
+++ b/dev-java/maven-bin/maven-bin-3.1.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/maven-bin/maven-bin-3.1.0.ebuild,v 1.1 2013/07/19 23:58:10 tomwij Exp $
+
+EAPI="5"
+
+inherit java-pkg-2
+
+MY_PN=apache-${PN%%-bin}
+MY_PV=${PV/_alpha/-alpha-}
+MY_P="${MY_PN}-${MY_PV}"
+MY_MV="${PV%%.*}"
+
+DESCRIPTION="Project Management and Comprehension Tool for Java"
+SRC_URI="mirror://apache/maven/maven-${MY_MV}/${PV}/binaries/${MY_P}-bin.tar.gz"
+HOMEPAGE="http://maven.apache.org/"
+
+LICENSE="Apache-2.0"
+SLOT="3.1"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="|| ( app-admin/eselect-java app-admin/eselect-maven )
+	dev-java/avalon-framework:4.1
+	dev-java/avalon-logkit:2.0
+	dev-java/commons-io:1
+	dev-java/juel:0
+	dev-java/log4j:0
+	dev-java/osgi-core-api:0
+	java-virtuals/servlet-api:2.4"
+
+RDEPEND=">=virtual/jdk-1.5
+	${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+MAVEN=${PN}-${SLOT}
+MAVEN_SHARE="/usr/share/${MAVEN}"
+
+java_prepare() {
+	rm -v "${S}"/bin/*.bat || die
+
+	chmod 644 "${S}"/boot/*.jar "${S}"/lib/*.jar "${S}"/conf/settings.xml || die
+
+	java-pkg_getjars avalon-framework-4.1,avalon-logkit-2.0,commons-io-1,juel,log4j,osgi-core-api,servlet-api-2.4 > /dev/null
+}
+
+# TODO we should use jars from packages, instead of what is bundled
+src_install() {
+	dodir "${MAVEN_SHARE}"
+
+	cp -Rp bin boot conf lib "${ED}/${MAVEN_SHARE}" || die "failed to copy"
+
+	java-pkg_regjar "${ED}/${MAVEN_SHARE}"/boot/*.jar
+	java-pkg_regjar "${ED}/${MAVEN_SHARE}"/lib/*.jar
+
+	dodoc NOTICE.txt README.txt
+
+	dodir /usr/bin
+	dosym "${MAVEN_SHARE}/bin/mvn" /usr/bin/mvn-${SLOT}
+
+	# See bug #342901.
+	echo "CONFIG_PROTECT=\"${MAVEN_SHARE}/conf\"" > "${T}/25${MAVEN}" || die
+	doenvd "${T}/25${MAVEN}"
+}
+
+pkg_postinst() {
+	eselect maven update mvn-${SLOT}
+}
+
+pkg_postrm() {
+	eselect maven update
+}