Version bump wrt #428488 by Jekyll Wu

Package-Manager: portage-2.2.0_alpha116/cvs/Linux x86_64

1 files changed, 58 insertions, 0 deletions

diff --git a/x11-terms/guake/guake-0.4.4.ebuild b/x11-terms/guake/guake-0.4.4.ebuild
new file mode 100644
index 000000000000..1c912ef1eced
--- /dev/null
+++ b/x11-terms/guake/guake-0.4.4.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/guake/guake-0.4.4.ebuild,v 1.1 2012/07/31 05:51:41 ssuominen Exp $
+
+EAPI=4
+
+GCONF_DEBUG=no
+GNOME2_LA_PUNT=yes
+
+PYTHON_DEPEND="2:2.7"
+
+inherit gnome2 python
+
+DESCRIPTION="A dropdown terminal made for the GTK+ desktops"
+HOMEPAGE="http://guake.org/"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+RDEPEND="dev-python/dbus-python
+	dev-python/gconf-python
+	dev-python/notify-python
+	dev-python/pygtk
+	dev-python/pyxdg
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/vte:0[python]"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+	G2CONF="--disable-static"
+
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	python_convert_shebangs 2 src/{guake,prefs.py}
+	>py-compile
+
+	gnome2_src_prepare
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_mod_optimize ${PN}
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup ${PN}
+}