Version bump and spell USE-flag

Package-Manager: portage-2.1.3.13

1 files changed, 45 insertions, 0 deletions

diff --git a/net-p2p/nicotine+/nicotine+-1.2.9.ebuild b/net-p2p/nicotine+/nicotine+-1.2.9.ebuild
new file mode 100644
index 000000000000..0436aeb97183
--- /dev/null
+++ b/net-p2p/nicotine+/nicotine+-1.2.9.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/nicotine+/nicotine+-1.2.9.ebuild,v 1.1 2007/10/14 11:31:25 armin76 Exp $
+
+inherit distutils eutils multilib toolchain-funcs
+
+DESCRIPTION="A fork of nicotine, a Soulseek client in Python"
+HOMEPAGE="http://nicotine-plus.sourceforge.net"
+SRC_URI="mirror://sourceforge/nicotine-plus/${P}.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="geoip spell vorbis"
+
+RDEPEND="virtual/python
+	>=dev-python/pygtk-2
+	vorbis? ( >=dev-python/pyvorbis-1.4-r1
+			  >=dev-python/pyogg-1 )
+	geoip? ( >=dev-python/geoip-python-0.2.0
+			 >=dev-libs/geoip-1.2.1 )
+	spell? ( dev-python/sexy-python )
+	!net-p2p/nicotine"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=sys-apps/sed-4"
+
+src_compile() {
+	distutils_src_compile
+
+	cd "${S}"/trayicon/
+	sed -i -e "s:/lib/:/$(get_libdir)/:" \
+		Makefile.in || die "sed failed"
+	./autogen.py
+	emake CC="$(tc-getCC)" || die "emake failed"
+}
+
+src_install() {
+	distutils_python_version
+	distutils_src_install --install-lib \
+		/usr/$(get_libdir)/python${PYVER}/site-packages
+
+	cd "${S}"/trayicon/
+	emake DESTDIR="${D}" install || die "emake install failed"
+}