Version bump

Package-Manager: portage-2.2.15/cvs/Linux x86_64
Manifest-Sign-Key: 0xA188FBD4

4 files changed, 191 insertions, 10 deletions

diff --git a/net-libs/gtk-vnc/ChangeLog b/net-libs/gtk-vnc/ChangeLog
index e0c1991ba2f8..a2c11c36d7dc 100644
--- a/net-libs/gtk-vnc/ChangeLog
+++ b/net-libs/gtk-vnc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gtk-vnc
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/ChangeLog,v 1.123 2014/11/13 12:30:40 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/ChangeLog,v 1.124 2015/02/12 13:16:54 pacho Exp $
+
+*gtk-vnc-0.5.4 (12 Feb 2015)
+
+  12 Feb 2015; Pacho Ramos <pacho@gentoo.org> +gtk-vnc-0.5.4.ebuild,
+  metadata.xml:
+  Version bump
 
   13 Nov 2014; Pacho Ramos <pacho@gentoo.org> -files/gtk-vnc-0.5.0-pod.patch,
   -files/gtk-vnc-0.5.0-pulseaudio-automagic.patch, -gtk-vnc-0.5.2.ebuild:
diff --git a/net-libs/gtk-vnc/Manifest b/net-libs/gtk-vnc/Manifest
index f0b699e6bcab..521b12f38043 100644
--- a/net-libs/gtk-vnc/Manifest
+++ b/net-libs/gtk-vnc/Manifest
@@ -2,13 +2,15 @@
 Hash: SHA256
 
 DIST gtk-vnc-0.5.3.tar.xz 408336 SHA256 d490a6c8f40e550d43aef0043ce3bec498ec220d5eb3dc5cdcff8fd561149caf SHA512 a5d81fcb8ee04f033a3aec2eed334e4237c8f4d7334e4875a149b5b385b0f0f0948d2d5227fbbfdccec8d192ba8bbc5f93dd83bb0d6604da25675662a9858cf2 WHIRLPOOL c2b6dc272843e0fce795fb4e082330f252a6f8413806e77b4ace78d63fead48634e647df96e2d6436b3c7a16013f6c2d18d377c762607ed2fd4dbd21e3f62fe3
+DIST gtk-vnc-0.5.4.tar.xz 418104 SHA256 488aa97a76ce6868160699cd45d4a0ee0fe6f0ad4631737c6ddd84450f6c9ce7 SHA512 068f7e29d40c677c9453364e33ab3a57e155dd0715299c8dee3f9933ecdb2e3bc4aea6dd722f5bc846d9b883e4f5a6de7b46742f004b348a551100ea7720da61 WHIRLPOOL 4d29f394a3ac5ea10584369f4a2290274a4be95c5d68c13e84e7ce990bf907243f16afc9b610ba973eebb3d137ca0fc4dce04df5f79afa1327a1c7aadcafaf5b
 EBUILD gtk-vnc-0.5.3.ebuild 4930 SHA256 cced8dc397f1730673c5f95672598f4051f7d2b9f00a778279e5b66702d7c13c SHA512 42f648ad94d82edbbe0f8fba0098c0b2d1afd662b21f47036c22027230041ae1bc4552b9b2027dcb286cce485d08eb2bc90b92c400fea34a3404b83ca2c0414c WHIRLPOOL 5171f4136f88b445c2749cc09d9b7ebce2ed5813779691f2dc64b9a46793c90b5872ff6f6aec06bf7fd15f20528e77b75a027c848fe0e3d95dd25cd043cf6086
-MISC ChangeLog 17715 SHA256 6b8682f4d63a44251898b6b91effdb1374928b1aae67439e9a5370f252a39270 SHA512 28d611ab70ad0b05590bed937007524b49b0f68bd1d5d3b74f02947d2b3558fab2a23a1967f32297bb29c23a3faeb3d3aca5ae75d06db57a6984e56dfb05c401 WHIRLPOOL 8a7d397b87d5df989cbbcc18c1fcac2833403d7048c5fb70b375beeeb77294e9e6d15aff71d0e3dea618a1c5d2c77630185c9710fda58fe5836d6edde0f5a675
-MISC metadata.xml 467 SHA256 e1b062faa95b1ecbd585784cf7e769d03ae58a222ec4d414abbfb7c5c0372099 SHA512 1e2a54fc822a29b1c08abcf748bb1041f109b3f3ad8ba4f702a024d23c3668455eb0e306be895fff2f00f6acee9f7ce48feff087acde004165e897a096ff34ec WHIRLPOOL 7a6e689d5fd832028593c0fd71c8a124d44b9f5722bfbcf4b1ab956bbff3018569c014c41579e14ad63ff22bc996c5e9fe1fa1a34cb09100d6275bf3dd5ef428
+EBUILD gtk-vnc-0.5.4.ebuild 4436 SHA256 b05838ddab58eaecddc658ab401b0031c1eecd55d14267cf0bb55a73ebdcddf4 SHA512 b0fde0081a554a6a404f4ce37c11da652541b93a9a1c5843adb648f3ce66c1f9273d38c5878d377d9746e3586c8775e494c81c3b2214c33f154837e5135a12c0 WHIRLPOOL a51e2ad21ca3607666bd8762515459f5e1520f5455756230812979d8828a6ff9e86aa53b7a0cd33719ceacc10666e748fc6d55f910d6326bc2ee796f5531d675
+MISC ChangeLog 17846 SHA256 5e6f5c27889547e9f37c76efd66396e78bdb5a887546c1fedf88e083d381dcac SHA512 9d1c2e08f1992c6a20a9cf220e20a5b81157e2e5e1b24f5a272d8b794cf69a5148bfd321da0ed0673d2f0e3334d4aeab03b430ea30a663acb123f8db583c8913 WHIRLPOOL 235c217e48dbde71c76579e04ac5ba0a484f20806b7a1d17208df3aed7b30704d10d762f35ca9a6c5e605415f418ae74c159420fcf30f2d05c1b4fc017f0bb7d
+MISC metadata.xml 289 SHA256 2574826df1cf0fc65b84f0fec7827d2080f8f6f0426e26c66342238331ef007e SHA512 0500d5ce2e5e4f443e71ccd4585152f65e001dab520f03a9eb374507d91d5fd5207db549bb1bd822727bb5bb3caee47d5e3f9cb1e8481210cb3827cc5b8e70ff WHIRLPOOL 5993207d1b15a292c5a6dbad793c48c34f83e13b4cc1e13d69b1566d6bf0154faf337074fff5b8d526fb8425e847c21a659d078a0df2ad93870adb21c16f8bc1
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2
 
-iEYEAREIAAYFAlRkpHEACgkQCaWpQKGI+9TqgACcDVPAoEYZ9a1ruV/TE9szNZjU
-aDoAn31Zmw9nsRwS2+WqcaaYWm4gBTnL
-=YFMR
+iEYEAREIAAYFAlTcp8cACgkQCaWpQKGI+9S2sACeOTllmwIDCuhl4ivfTazd5hLb
+fCcAnA0ZxiyNZDICq9qJ+u8a+0XCR/nn
+=CT7n
 -----END PGP SIGNATURE-----
diff --git a/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild b/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild
new file mode 100644
index 000000000000..a5ad1f32c3fc
--- /dev/null
+++ b/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild
@@ -0,0 +1,176 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild,v 1.1 2015/02/12 13:16:54 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-r1 vala
+
+DESCRIPTION="VNC viewer widget for GTK"
+HOMEPAGE="https://wiki.gnome.org/Projects/gtk-vnc"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="examples +gtk3 +introspection pulseaudio python sasl vala"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	vala? ( gtk3 introspection )
+"
+
+# libview is used in examples/gvncviewer -- no need
+# glib-2.30.1 needed to avoid linking failure due to .la files (bug #399129)
+COMMON_DEPEND="
+	>=dev-libs/glib-2.30.1:2
+	>=dev-libs/libgcrypt-1.4.2:0
+	dev-libs/libgpg-error
+	>=net-libs/gnutls-2.12
+	>=x11-libs/cairo-1.2
+	>=x11-libs/gtk+-2.18:2
+	x11-libs/libX11
+	gtk3? ( >=x11-libs/gtk+-2.91.3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.4 )
+	pulseaudio? ( media-sound/pulseaudio )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2:2[${PYTHON_USEDEP}] )
+	sasl? ( dev-libs/cyrus-sasl )
+"
+RDEPEND="${COMMON_DEPEND}"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-lang/perl-5
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-0.9.4 )
+"
+# eautoreconf requires gnome-common
+
+GTK2_BUILDDIR="${WORKDIR}/${P}_gtk2"
+GTK3_BUILDDIR="${WORKDIR}/${P}_gtk3"
+
+src_prepare() {
+	mkdir -p "${GTK2_BUILDDIR}" || die
+	mkdir -p "${GTK3_BUILDDIR}" || die
+	prepare_python() {
+		mkdir -p "${BUILD_DIR}" || die
+	}
+	if use python; then
+		python_foreach_impl prepare_python
+	fi
+
+	# Fix incorrect codegendir check: h2def.py is in pygobject, not pygtk, upstream bug#744393
+	sed -e 's/codegendir pygtk-2.0/codegendir pygobject-2.0/g' \
+		-i src/Makefile.* || die
+
+	# libtool seems unable to find this via VPATH so help it
+	sed -r "s:(gtkvnc_la_LIBADD =) libgtk-vnc-.*\.la:\1 ${GTK2_BUILDDIR}/src/libgtk-vnc-1.0.la:" \
+		-i src/Makefile.{am,in} || die
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf
+	myconf="
+		$(use_with examples) \
+		$(use_enable introspection) \
+		$(use_with pulseaudio) \
+		$(use_with sasl) \
+		--with-coroutine=gthread \
+		--without-libview \
+		--disable-static \
+		--disable-vala"
+
+	cd "${GTK2_BUILDDIR}" || die
+	einfo "Running configure in ${GTK2_BUILDDIR}"
+	ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
+		--with-python=no \
+		--with-gtk=2.0
+
+	configure_python() {
+		ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
+			$(use_with python) \
+			--with-gtk=2.0
+	}
+	if use python; then
+		python_foreach_impl run_in_build_dir configure_python
+	fi
+
+	if use gtk3; then
+		cd "${GTK3_BUILDDIR}" || die
+		einfo "Running configure in ${GTK3_BUILDDIR}"
+		# Python support is via gobject-introspection
+		# Ex: from gi.repository import GtkVnc
+		ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
+			$(use_enable vala) \
+			--with-python=no \
+			--with-gtk=3.0
+	fi
+}
+
+src_compile() {
+	cd "${GTK2_BUILDDIR}" || die
+	einfo "Running make in ${GTK2_BUILDDIR}"
+	gnome2_src_compile
+
+	compile_python() {
+		cd "${BUILD_DIR}"/src || die
+		# CPPFLAGS set to help find includes for gvnc.override
+		emake gtkvnc.la \
+			VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
+			CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
+	}
+	if use python; then
+		python_foreach_impl run_in_build_dir compile_python
+	fi
+
+	if use gtk3; then
+		cd "${GTK3_BUILDDIR}" || die
+		einfo "Running make in ${GTK3_BUILDDIR}"
+		gnome2_src_compile
+	fi
+}
+
+src_test() {
+	cd "${GTK2_BUILDDIR}" || die
+	einfo "Running make check in ${GTK2_BUILDDIR}"
+	default
+
+	if use gtk3; then
+		cd "${GTK3_BUILDDIR}" || die
+		einfo "Running make check in ${GTK3_BUILDDIR}"
+		default
+	fi
+}
+
+src_install() {
+	cd "${GTK2_BUILDDIR}" || die
+	einfo "Running make install in ${GTK2_BUILDDIR}"
+	gnome2_src_install
+
+	install_python() {
+		cd "${BUILD_DIR}"/src || die
+		emake install-pyexecLTLIBRARIES DESTDIR="${D}" \
+			VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
+			CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
+	}
+	if use python; then
+		python_foreach_impl run_in_build_dir install_python
+	fi
+
+	if use gtk3; then
+		cd "${GTK3_BUILDDIR}" || die
+		einfo "Running make install in ${GTK3_BUILDDIR}"
+		gnome2_src_install
+	fi
+}
diff --git a/net-libs/gtk-vnc/metadata.xml b/net-libs/gtk-vnc/metadata.xml
index 4cb5547ff1a7..3a15c3288b0d 100644
--- a/net-libs/gtk-vnc/metadata.xml
+++ b/net-libs/gtk-vnc/metadata.xml
@@ -5,8 +5,5 @@
   <herd>virtualization</herd>
   <use>
     <flag name="gtk3">Build the gtk3 gtk-vnc library and other gtk3 assets</flag>
-    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
-		for introspection</flag>
-    <flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
   </use>
 </pkgmetadata>