Use newer Debian patchset (bug #479882).

Package-Manager: portage-2.2.8-r1/cvs/Linux x86_64
Manifest-Sign-Key: 0xA792A613

1 files changed, 65 insertions, 0 deletions

diff --git a/net-analyzer/dsniff/dsniff-2.4_beta1-r6.ebuild b/net-analyzer/dsniff/dsniff-2.4_beta1-r6.ebuild
new file mode 100644
index 000000000000..9ad830e19d1f
--- /dev/null
+++ b/net-analyzer/dsniff/dsniff-2.4_beta1-r6.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/dsniff/dsniff-2.4_beta1-r6.ebuild,v 1.1 2014/03/14 19:23:53 jer Exp $
+
+EAPI=5
+inherit autotools eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="A collection of tools for network auditing and penetration testing"
+HOMEPAGE="http://monkey.org/~dugsong/dsniff/"
+SRC_URI="
+	http://monkey.org/~dugsong/${PN}/beta/${P/_beta/b}.tar.gz
+	mirror://debian/pool/main/d/${PN}/${PN}_2.4b1+debian-22.1.debian.tar.gz
+"
+LICENSE="BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="X"
+
+DEPEND="net-libs/libpcap
+	>=net-libs/libnet-1.1.2.1-r1
+	>=net-libs/libnids-1.21
+	>=dev-libs/openssl-0.9.6e
+	>=sys-libs/db-4.2.52_p4
+	X? ( x11-libs/libXmu )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${P/_beta1/}"
+
+src_prepare() {
+	# Debian patchset, needs to be applied in the exact order that "series"
+	# lists or patching will fail.
+	# Bug #479882
+	epatch $(
+		for file in $(< "${WORKDIR}"/debian/patches/series ); do
+			printf "%s/debian/patches/%s " "${WORKDIR}" "${file}"
+		done
+	)
+
+	# Bug 125084
+	epatch "${FILESDIR}"/${PV}-httppostfix.patch
+
+	# various Makefile.in patches
+	epatch "${FILESDIR}"/${PV}-make.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with X x) \
+		|| die "econf failed"
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake install install_prefix="${D}"
+	dodir /etc/dsniff
+	cp "${D}"/usr/share/dsniff/{dnsspoof.hosts,dsniff.{magic,services}} \
+		"${D}"/etc/dsniff/
+	dodoc CHANGES README TODO
+}