version bump

Package-Manager: portage-2.2.0_alpha81/cvs/Linux x86_64

3 files changed, 285 insertions, 5 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index 899ef800b388..1a7bd869eb5b 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.507 2011/12/15 11:25:11 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.508 2011/12/15 11:30:44 aballier Exp $
+
+*ffmpeg-0.9 (15 Dec 2011)
+
+  15 Dec 2011; Alexis Ballier <aballier@gentoo.org> +ffmpeg-0.9.ebuild:
+  version bump
 
   15 Dec 2011; Alexis Ballier <aballier@gentoo.org> ffmpeg-9999.ebuild:
   disable all asm on x86 with pic, this should be much slower but, at least,
diff --git a/media-video/ffmpeg/Manifest b/media-video/ffmpeg/Manifest
index 6272f85a892d..eaf37fd66e3b 100644
--- a/media-video/ffmpeg/Manifest
+++ b/media-video/ffmpeg/Manifest
@@ -5,16 +5,18 @@ AUX ffmpeg-0.7.6-fix_ppc64_32ul.patch 1094 RMD160 b765f1f8420701e6d9447391dd498f
 DIST ffmpeg-0.7.7.tar.bz2 4531586 RMD160 1123b0e38811dfd4f4f1cb0f7678518f90849034 SHA1 30cc01d359d99bb6304b7fecbd5ff909843d93f4 SHA256 7231846b0d59d3fc3c0ed8370a35c823b59b84de3e92d2d8223b3bef3b92c8e1
 DIST ffmpeg-0.7.8.tar.bz2 4530406 RMD160 8f69a6bc5caaba4e3d440c2d5dc96a946454a52c SHA1 df4983c028a61d4bf3baceab3bae535b91b8928a SHA256 548197968e69b732c12b2cad3173eb6933a9573a7b1f5b29be36d31b9977c9f3
 DIST ffmpeg-0.8.7.tar.bz2 4527751 RMD160 5ccc0cfcfaf77b2f7e7cc51190d00bc22db85866 SHA1 e6c391769b1e45afd8e3f41b734c17ba1437f4a9 SHA256 e074656390bfff51c2915d3334306dd7748bab8589a8d04128143c7b8962d0e1
+DIST ffmpeg-0.9.tar.bz2 4954965 RMD160 56e1e240363d4f1bc09390f5a3893a1b6b362908 SHA1 5f4118496ebe8fc37e8f11cf0303f6f7c85756f9 SHA256 2a9eb7795e6c1ad746aa2cc0fce9f71ec3763f610e362530ab277c6bc327d705
 EBUILD ffmpeg-0.7.7.ebuild 8434 RMD160 64ae02f0921dcb59c8850d102fd36be8b83d3ea4 SHA1 a04df51a15709a9b669b8e1ff8e4e7582fce6949 SHA256 2530241330f21149e401ec15fc448acfcbcd5b16b728ae0624dba422b449947f
 EBUILD ffmpeg-0.7.8.ebuild 8436 RMD160 34282efc2ce033b2015a7916975a14eb493d52e5 SHA1 27a7721fb83ee62e7a0eb36bdbe773cf442c67f1 SHA256 3f34e02690bd4f56e4562d223226375ae19eabfa4ca52a29e2d43f828b972318
 EBUILD ffmpeg-0.8.7.ebuild 8020 RMD160 7d2e2c1cf5de1f0d7e6af73d4c631705a45c47fb SHA1 02f250e6951e918eb1089a29a65c5dfade548835 SHA256 156ac6a17e91c52d8df28a2a71c77b6ad518da9a727c3416bee1df35777963e4
+EBUILD ffmpeg-0.9.ebuild 8243 RMD160 1a53d5f13da10ca48e7a366c7afa0562b26da0d1 SHA1 9962281411e6132e670640e042a5d08e0e9dc092 SHA256 3101496a71f30b51f1e8c052d62497eaf2e0ee1640c192634746c6af5f2ee3f9
 EBUILD ffmpeg-9999.ebuild 8287 RMD160 ddf5b46aa60697f102d0a4fb0b1311d9c7bf6d3c SHA1 73c53a9087ef19f984d405306e7aabb93c548d79 SHA256 23afed5b6e6464f92ada61f10e52170738e140245720474481dd684bf525988c
-MISC ChangeLog 72916 RMD160 ea41bf4947a69a367adc9b0e786167b6a71ed960 SHA1 1ad7585e89019edefc58b683a95c4104c74caf57 SHA256 31b200974d36ec889ecc0b825da126369755b5b7af22f6e35548312baae750e7
+MISC ChangeLog 73031 RMD160 0f4b019a9b81c59ff00bf1104ba4ac3c3376350f SHA1 1201756725d48f882c0b40759fb68c173446f76b SHA256 7cdf97ca75295a1f938c738585b3c3fc4e91d764658a3dc5faef46811eb88e7a
 MISC metadata.xml 3136 RMD160 83498fadc792f93d602a65caf742e4cd1c379615 SHA1 61ecdedb07c4d97cf5f3a665e9d301c07657d863 SHA256 6a36d874d9bd519aadc8c406f9f1a07b60dd35c41a41ba8484f602b87f8ed85e
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iEYEARECAAYFAk7p2RwACgkQvFcC4BYPU0r0hwCdGSX7FurCTEKvL0Xk0aiU+IzU
-LAgAoLwuY2BwwLjvDtr3e87EaKTsZEFR
-=wrUI
+iEYEARECAAYFAk7p2mkACgkQvFcC4BYPU0pCAACgha/vuZftXz4BrXfMOJi2pPYu
+SSgAnRXdqDP5flJRZpEpd/L6NcJY/RCY
+=LHHU
 -----END PGP SIGNATURE-----
diff --git a/media-video/ffmpeg/ffmpeg-0.9.ebuild b/media-video/ffmpeg/ffmpeg-0.9.ebuild
new file mode 100644
index 000000000000..9d7888e572fe
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.9.ebuild
@@ -0,0 +1,273 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.9.ebuild,v 1.1 2011/12/15 11:30:44 aballier Exp $
+
+EAPI="4"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~hppa ~x86-fbsd"
+fi
+IUSE="
+	aac aacplus alsa amr ass bindist +bzip2 cdio celt cpudetection debug dirac doc
+	+encode faac frei0r gnutls gsm +hardcoded-tables ieee1394 jack jpeg2k libv4l
+	modplug mp3 network openal openssl oss pic pulseaudio +qt-faststart rtmp
+	schroedinger sdl speex static-libs test theora threads truetype v4l vaapi
+	vdpau vorbis vpx X x264 xvid +zlib
+	"
+
+# String for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon iwmmxt"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ass? ( media-libs/libass )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio )
+	celt? ( >=media-libs/celt-0.11.1 )
+	dirac? ( media-video/dirac )
+	encode? (
+		aac? ( media-libs/vo-aacenc )
+		aacplus? ( media-libs/libaacplus )
+		amr? ( media-libs/vo-amrwbenc )
+		faac? ( media-libs/faac )
+		mp3? ( >=media-sound/lame-3.98.3 )
+		theora? ( >=media-libs/libtheora-1.1.1[encode] media-libs/libogg )
+		vorbis? ( media-libs/libvorbis media-libs/libogg )
+		x264? ( >=media-libs/x264-0.0.20111017 )
+		xvid? ( >=media-libs/xvid-1.1.0 )
+	)
+	frei0r? ( media-plugins/frei0r-plugins )
+	gnutls? ( net-libs/gnutls )
+	gsm? ( >=media-sound/gsm-1.0.12-r1 )
+	ieee1394? ( media-libs/libdc1394 sys-libs/libraw1394 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2 )
+	libv4l? ( media-libs/libv4l )
+	modplug? ( media-libs/libmodplug )
+	openal? ( >=media-libs/openal-1.1 )
+	pulseaudio? ( media-sound/pulseaudio )
+	rtmp? ( >=media-video/rtmpdump-2.2f )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video] )
+	schroedinger? ( media-libs/schroedinger )
+	speex? ( >=media-libs/speex-1.2_beta3 )
+	truetype? ( media-libs/freetype:2 )
+	vaapi? ( >=x11-libs/libva-0.32 )
+	vdpau? ( x11-libs/libvdpau )
+	vpx? ( >=media-libs/libvpx-0.9.6 )
+	X? ( x11-libs/libX11 x11-libs/libXext x11-libs/libXfixes )
+	zlib? ( sys-libs/zlib )
+	!media-video/qt-faststart
+"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( dev-util/pkgconfig )
+	doc? ( app-text/texi2html )
+	gnutls? ( dev-util/pkgconfig )
+	ieee1394? ( dev-util/pkgconfig )
+	libv4l? ( dev-util/pkgconfig )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( dev-util/pkgconfig )
+	schroedinger? ( dev-util/pkgconfig )
+	test? ( net-misc/wget )
+	truetype? ( dev-util/pkgconfig )
+	v4l? ( sys-kernel/linux-headers )
+"
+# faac is license-incompatible with ffmpeg
+REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
+	libv4l? ( v4l )"
+
+S=${WORKDIR}/${P/_/-}
+
+src_prepare() {
+	if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		export revision=git-N-${FFMPEG_REVISION}
+	fi
+}
+
+src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	# Set to --enable-version3 if (L)GPL-3 is required
+	local version3=""
+
+	# enabled by default
+	for i in debug doc network vaapi vdpau zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+	use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
+	use gnutls && myconf="${myconf} --enable-gnutls"
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+		use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+		for i in theora vorbis x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
+		use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf="${myconf} --enable-libcdio"
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	use openal && myconf="${myconf} --enable-openal"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf="${myconf} --disable-indev=v4l"
+	use v4l || myconf="${myconf} --disable-indev=v4l2"
+	for i in alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	use pulseaudio && myconf="${myconf} --enable-libpulse"
+	use libv4l && myconf="${myconf} --enable-libv4l2"
+	# Outdevs
+	for i in alsa oss sdl ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf="${myconf} --enable-frei0r"
+	use truetype && myconf="${myconf} --enable-libfreetype"
+	use ass && myconf="${myconf} --enable-libass"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+	for i in celt gsm dirac modplug rtmp schroedinger speex vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
+	done
+	if use pic ; then
+		myconf="${myconf} --enable-pic"
+		# disable asm code if PIC is required
+		# as the provided asm decidedly is not PIC for x86.
+		use x86 && myconf="${myconf} --disable-asm"
+	fi
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		${version3}
+		--enable-postproc
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	cd "${S}"
+	./configure \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--mandir="${EPREFIX}/usr/share/man" \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		--optflags="" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		$(use_enable static-libs static) \
+		${myconf} || die
+}
+
+src_compile() {
+	#252269
+	emake version.h
+	emake
+
+	if use qt-faststart; then
+		tc-export CC
+		emake -C tools qt-faststart
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-man
+
+	dodoc Changelog README INSTALL
+	dodoc -r doc/*
+
+	if use qt-faststart; then
+		dobin tools/qt-faststart
+	fi
+}
+
+src_test() {
+	if use encode ; then
+		LD_LIBRARY_PATH="${S}/libpostproc:${S}/libswscale:${S}/libavcodec:${S}/libavdevice:${S}/libavfilter:${S}/libavformat:${S}/libavutil" \
+			emake fate
+	else
+		ewarn "Tests fail without USE=encode, skipping"
+	fi
+}