restore some ABI that appears to cause virtualbox-bin to fail (bug #310793)

Package-Manager: portage-2.1.8.3/cvs/Linux i686

4 files changed, 165 insertions, 5 deletions

diff --git a/media-libs/libsdl/ChangeLog b/media-libs/libsdl/ChangeLog
index 350eec900b63..ce07dd9a9cd8 100644
--- a/media-libs/libsdl/ChangeLog
+++ b/media-libs/libsdl/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libsdl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.169 2010/07/20 15:09:54 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.170 2010/10/26 16:03:26 mr_bones_ Exp $
+
+*libsdl-1.2.14-r4 (26 Oct 2010)
+
+  26 Oct 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  libsdl-1.2.14-r3.ebuild, +libsdl-1.2.14-r4.ebuild:
+  restore some ABI that appears to cause virtualbox-bin to fail (bug
+  #310793)
 
 *libsdl-1.2.14-r3 (20 Jul 2010)
 
diff --git a/media-libs/libsdl/Manifest b/media-libs/libsdl/Manifest
index ff5c4dc7bd3e..49d4e3a0d276 100644
--- a/media-libs/libsdl/Manifest
+++ b/media-libs/libsdl/Manifest
@@ -9,7 +9,8 @@ DIST SDL-1.2.14.tar.gz 4014154 RMD160 a3a9a691f5510eb5327ca159a034f55a70cb5801 S
 EBUILD libsdl-1.2.13-r1.ebuild 4408 RMD160 366a3f3f96baca55bc308eed5c5a7bb5b0234a33 SHA1 d87306a3c618de1499dc53eae95f131c58ab76f2 SHA256 f9f729e942b19ecae67c3a497bcc6387b297e0bdf10efa4b4fec607690e8b4be
 EBUILD libsdl-1.2.14-r1.ebuild 4408 RMD160 acab2efeef1bf4dfb68010ba959504256b70234d SHA1 70194a0dc921a0caffd13fc26d5ff998b3431670 SHA256 ca2acf34a6a856343500c13f95ad6e7be8c881006d93add6eb43e307bb5203a4
 EBUILD libsdl-1.2.14-r2.ebuild 4564 RMD160 d4db0b64500538d1766b2526504c3451ffe0de77 SHA1 b692d3548e7ac2cb1117c50252921f2b5473d1e8 SHA256 ccd9274858772a198ddbd388b438a0cbb93749bb0b18d149dc5ed80c1740c5ce
-EBUILD libsdl-1.2.14-r3.ebuild 4564 RMD160 5f6cdd4f8e546590803fa0ec5dd83034f176af94 SHA1 c75e37f81e9e9fbd3c9b8a98b0ac85cd1b9951a2 SHA256 411b7b26667ea838afa1703cdde8304cd36b22dcafb1198cddee4bb8dc8ce952
+EBUILD libsdl-1.2.14-r3.ebuild 4539 RMD160 4285c807df444a241b3cd1a981b4082af24b3cbc SHA1 c8bb5bf9fd94c2b96f92ac7049cd0ee8aa451f3e SHA256 21501a1a7f1b209cabc183c7b9a0f4e801394728c04d60353d28b200aaa60646
+EBUILD libsdl-1.2.14-r4.ebuild 4539 RMD160 7b05bdfc81e02537a660ccbfa21847cd3c876e1d SHA1 208684e35fb845761434b7eb0316f87a83e97310 SHA256 1fec5daa486db169086400a00b47e6be39401e09378c881427492e94f4f4ef74
 EBUILD libsdl-1.2.14.ebuild 4218 RMD160 cf217f2af01d585f4f4ca0afcd5f0a01e9bc89c0 SHA1 a1ba08c8d034e5ac1eb591721c0144b65a3c9396 SHA256 e7ca5921e4625d7a73d0383b89014a5eb41866f9391857327590a58d5cf684fd
-MISC ChangeLog 26324 RMD160 be641ebf88f4ee50b53764ebe3928c3d7b187d7d SHA1 c5c2d8411c35d9754946b4f73fcf4c3979451210 SHA256 ed495f281beb224fd8d6f644f951d68d4d2e23cffb36b563a0cfdf10e23ff147
+MISC ChangeLog 26546 RMD160 85c3e1e175029fe0a02eec42e3e0e5f5ff80f9f8 SHA1 a6dca7ef0f657e8ef72e1539b9794d9f83075a84 SHA256 91da316b345359830c9a74b0d079b602ff71b1e190a2e1c503415c2e13a7d6dd
 MISC metadata.xml 1357 RMD160 f76f0ef20941fc2c320b8a13f497dcb43f124cc9 SHA1 e5c05312f46bc682fc7fed1c7cec23bbdb59cd07 SHA256 a19b0d85c597bbe4d3dffa744d2ed9365660f8082145ab6b6f0813e36e174827
diff --git a/media-libs/libsdl/libsdl-1.2.14-r3.ebuild b/media-libs/libsdl/libsdl-1.2.14-r3.ebuild
index 625527ca3840..febf598cda24 100644
--- a/media-libs/libsdl/libsdl-1.2.14-r3.ebuild
+++ b/media-libs/libsdl/libsdl-1.2.14-r3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.14-r3.ebuild,v 1.1 2010/07/20 15:09:54 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.14-r3.ebuild,v 1.2 2010/10/26 16:03:26 mr_bones_ Exp $
 
 EAPI=2
 inherit flag-o-matic multilib toolchain-funcs eutils libtool
@@ -120,7 +120,6 @@ src_configure() {
 		--disable-pulseaudio-shared \
 		--disable-arts-shared \
 		--disable-nas-shared \
-		--disable-x11-shared \
 		--disable-osmesa-shared \
 		$(use_enable oss) \
 		$(use_enable alsa) \
diff --git a/media-libs/libsdl/libsdl-1.2.14-r4.ebuild b/media-libs/libsdl/libsdl-1.2.14-r4.ebuild
new file mode 100644
index 000000000000..5d6694389e7a
--- /dev/null
+++ b/media-libs/libsdl/libsdl-1.2.14-r4.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.14-r4.ebuild,v 1.1 2010/10/26 16:03:26 mr_bones_ Exp $
+
+EAPI=2
+inherit flag-o-matic multilib toolchain-funcs eutils libtool
+
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="http://www.libsdl.org/"
+SRC_URI="http://www.libsdl.org/release/SDL-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+# WARNING:
+# if you disable the audio, video, joystick use flags or turn on the custom-cflags use flag
+# in USE and something breaks, you pick up the pieces.  Be prepared for
+# bug reports to be marked INVALID.
+IUSE="oss alsa nas X dga xv xinerama fbcon directfb ggi svga tslib aalib opengl libcaca +audio +video +joystick custom-cflags pulseaudio ps3 static-libs"
+
+RDEPEND="audio? ( >=media-libs/audiofile-0.1.9 )
+	alsa? ( media-libs/alsa-lib )
+	nas? (
+		media-libs/nas
+		x11-libs/libXt
+		x11-libs/libXext
+		x11-libs/libX11
+	)
+	X? (
+		x11-libs/libXt
+		x11-libs/libXext
+		x11-libs/libX11
+		x11-libs/libXrandr
+	)
+	directfb? ( >=dev-libs/DirectFB-0.9.19 )
+	ggi? ( >=media-libs/libggi-2.0_beta3 )
+	svga? ( >=media-libs/svgalib-1.4.2 )
+	aalib? ( media-libs/aalib )
+	libcaca? ( >=media-libs/libcaca-0.9-r1 )
+	opengl? ( virtual/opengl virtual/glu )
+	ppc64? ( ps3? ( sys-libs/libspe2 ) )
+	tslib? ( x11-libs/tslib )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+	nas? (
+		x11-proto/xextproto
+		x11-proto/xproto
+	)
+	X? (
+		x11-proto/xextproto
+		x11-proto/xproto
+	)
+	x86? ( || ( >=dev-lang/yasm-0.6.0 >=dev-lang/nasm-0.98.39-r3 ) )"
+
+S=${WORKDIR}/SDL-${PV}
+
+pkg_setup() {
+	if use !audio || use !video || use !joystick ; then
+		ewarn "Since you've chosen to turn off some of libsdl's functionality,"
+		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
+		ewarn "libsdl with the audio, video, and joystick flags in USE."
+		ewarn "You need to know what you're doing to selectively turn off parts of libsdl."
+		epause 30
+	fi
+	if use custom-cflags ; then
+		ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
+		ewarn "don't bother filing libsdl-related bugs until trying to remerge"
+		ewarn "libsdl without the custom-cflags use flag in USE."
+		epause 10
+	fi
+}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-1.2.13-sdl-config.patch \
+		"${FILESDIR}"/${P}-click.patch
+
+	elibtoolize
+}
+
+src_configure() {
+	local myconf=
+	if [[ $(tc-arch) != "x86" ]] ; then
+		myconf="${myconf} --disable-nasm"
+	else
+		myconf="${myconf} --enable-nasm"
+	fi
+	use custom-cflags || strip-flags
+	use audio || myconf="${myconf} --disable-audio"
+	use video \
+		&& myconf="${myconf} --enable-video-dummy" \
+		|| myconf="${myconf} --disable-video"
+	use joystick || myconf="${myconf} --disable-joystick"
+
+	local directfbconf="--disable-video-directfb"
+	if use directfb ; then
+		# since DirectFB can link against SDL and trigger a
+		# dependency loop, only link against DirectFB if it
+		# isn't broken #61592
+		echo 'int main(){}' > directfb-test.c
+		$(tc-getCC) directfb-test.c -ldirectfb 2>/dev/null \
+			&& directfbconf="--enable-video-directfb" \
+			|| ewarn "Disabling DirectFB since libdirectfb.so is broken"
+	fi
+
+	myconf="${myconf} ${directfbconf}"
+
+	econf \
+		--disable-rpath \
+		--disable-arts \
+		--disable-esd \
+		--enable-events \
+		--enable-cdrom \
+		--enable-threads \
+		--enable-timers \
+		--enable-file \
+		--enable-cpuinfo \
+		--disable-alsa-shared \
+		--disable-esd-shared \
+		--disable-pulseaudio-shared \
+		--disable-arts-shared \
+		--disable-nas-shared \
+		--disable-osmesa-shared \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable pulseaudio) \
+		$(use_enable nas) \
+		$(use_enable X video-x11) \
+		$(use_enable dga) \
+		$(use_enable xv video-x11-xv) \
+		$(use_enable xinerama video-x11-xinerama) \
+		$(use_enable X video-x11-xrandr) \
+		$(use_enable dga video-dga) \
+		$(use_enable fbcon video-fbcon) \
+		$(use_enable ggi video-ggi) \
+		$(use_enable svga video-svga) \
+		$(use_enable aalib video-aalib) \
+		$(use_enable libcaca video-caca) \
+		$(use_enable opengl video-opengl) \
+		$(use_enable ps3 video-ps3) \
+		$(use_enable tslib input-tslib) \
+		$(use_with X x) \
+		$(use_enable static-libs static) \
+		--disable-video-x11-xme \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	use static-libs || rm -f "${D}"/usr/$(get_libdir)/lib*.la
+	dodoc BUGS CREDITS README README-SDL.txt README.CVS TODO WhatsNew
+	dohtml -r ./
+}