Revision bumps for security bug #84076. Stable amd64, sparc, x86.

Package-Manager: portage-2.0.51.19

1 files changed, 49 insertions, 0 deletions

diff --git a/media-libs/libexif/libexif-0.6.10-r1.ebuild b/media-libs/libexif/libexif-0.6.10-r1.ebuild
new file mode 100644
index 000000000000..b521ac5e6b56
--- /dev/null
+++ b/media-libs/libexif/libexif-0.6.10-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libexif/libexif-0.6.10-r1.ebuild,v 1.1 2005/03/10 23:30:09 eradicator Exp $
+
+inherit eutils
+
+DESCRIPTION="Library for parsing, editing, and saving EXIF data"
+HOMEPAGE="http://libexif.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-macos"
+IUSE="nls"
+
+DEPEND="dev-util/pkgconfig"
+RDEPEND="virtual/libc"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+	epatch ${FILESDIR}/libexif-0.6-CAN-2005-0664.patch
+}
+
+src_compile() {
+	econf $(use_enable nls) || die
+	emake || die
+}
+
+src_install() {
+	dodir /usr/$(get_libdir)
+	dodir /usr/include/libexif
+	use nls && dodir /usr/share/locale
+	dodir /usr/$(get_libdir)/pkgconfig
+
+	make DESTDIR="${D}" install || die
+
+	dodoc ChangeLog README
+
+	# installs a blank directory for whatever broken reason
+	use nls || rm -rf ${D}/usr/share/locale
+
+	# Keep around old lib
+	preserve_old_lib /usr/$(get_libdir)/libexif.so.9
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/libexif.so.9
+}