media-gfx/gimp: Set precedence of Gimp on PDF files to zero (bug #321111)

Package-Manager: portage-2.1.10.11/cvs/Linux x86_64

4 files changed, 279 insertions, 5 deletions

diff --git a/media-gfx/gimp/ChangeLog b/media-gfx/gimp/ChangeLog
index e29d78b626df..ecbf335ac669 100644
--- a/media-gfx/gimp/ChangeLog
+++ b/media-gfx/gimp/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/gimp
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.334 2011/09/02 17:39:01 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.335 2011/09/02 20:48:14 sping Exp $
+
+*gimp-2.7.3-r1 (02 Sep 2011)
+*gimp-2.6.11-r4 (02 Sep 2011)
+
+  02 Sep 2011; Sebastian Pipping <sping@gentoo.org> +gimp-2.6.11-r4.ebuild,
+  +gimp-2.7.3-r1.ebuild:
+  Set precedence of Gimp on PDF files to zero (bug #321111)
 
 *gimp-2.6.11-r3 (02 Sep 2011)
 
diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 2aad7fa6dce6..31e3387573bb 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -12,14 +12,16 @@ DIST gimp-2.7.3.tar.bz2 18206530 RMD160 5740b1b62b0fca255d0ca046477c21ab9c57a5ca
 EBUILD gimp-2.6.11-r1.ebuild 3248 RMD160 324ff1505eeed9d839cc9695df3289dff0e5bf6e SHA1 b163b4ce5567abeb087b4f50eb4bfc2bb431a040 SHA256 07c2eafd3ce4e49f05a7b154b30be3f40a069e6617e1538c5e97d901dc424925
 EBUILD gimp-2.6.11-r2.ebuild 3259 RMD160 0f869b84f27b578b0c50da27545afc724ec236fc SHA1 4159ab5be4c896576ab9ca18d5b68b544665d23a SHA256 437a9aeff3e6c03814f0ce2912b8037e2005876aee294be79804a7765aa29180
 EBUILD gimp-2.6.11-r3.ebuild 3442 RMD160 6c00cf7623c95dd96c2ff7ff4dbc20b85f0626ee SHA1 78a5a60ff16cbe6b60db16c141ad5c330247ab68 SHA256 8ef54a8f1812a0f951c621c1adfc556629c65cd151411679bb197a9202a3c406
+EBUILD gimp-2.6.11-r4.ebuild 3599 RMD160 716dc59bece8d051abbff3342792967c3bbad8c8 SHA1 b084de1d1852f47b47538c436a1e821fd83396d6 SHA256 a2092b38bc668c4d642957d141139e8a020361d2ae1f4405b89c741abbde7fb5
+EBUILD gimp-2.7.3-r1.ebuild 3390 RMD160 9b078def828d702fee05f0be342d3fee26774746 SHA1 6461bdf711374d5f8e2dd50b2e6387984b668d56 SHA256 244d4182eed991e506bfec846cf71ef089a699cd91d1787472f8907e68aa3ca5
 EBUILD gimp-2.7.3.ebuild 3230 RMD160 6b38a0a065ec8425f8a4f148091d9592654df883 SHA1 ac744bc74f5f667dde7f81b51c2119e417bf2f8c SHA256 7158983e329c36765e33024aef0559640ea49a9f1e6bcca25508129d7663a2e4
 EBUILD gimp-9999.ebuild 3443 RMD160 b8468c1dd4625ab3267f66af056eac8a89596c53 SHA1 010d83b218f0ae999a81e683ea0e4ededf0fed00 SHA256 464b8c58ff4a11584d3eda30aa2c18be662e94a0cd7edac9532fc7b6e56cca4d
-MISC ChangeLog 45777 RMD160 cea66fd7ad7dcaab4c7f572d8877f7eea53ac9b3 SHA1 d75007c37a2ba6c0266d9a2356b32d6b313219f4 SHA256 1235c767f3bc38f4ff73f6f923ceeff70b9368efc5f3263a73fd42c17b0fda0f
+MISC ChangeLog 45999 RMD160 35414ad742fde14187c9352a5ce09a42deed5b83 SHA1 df9fc97d63e6eb43ea5c7d0e70be3fb55d4e9232 SHA256 0752f90ad442f6434c4508b15f046d96c0a2ba3daeb9bfe43f6a77b7b44324c3
 MISC metadata.xml 366 RMD160 5ae566a82314bb47784051f6ca13fc1a9ecd137e SHA1 dce399814102ba9802439497439e2e00ecc3b82e SHA256 380bccccb72b527f81e02fd37b41b584316fcd7c802b959b8eae27fcef0c0db5
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.18 (GNU/Linux)
 
-iEYEARECAAYFAk5hFLIACgkQsAvGakAaFgDLkgCbB2GmPmbPxXMwe1PYrc0YTKqG
-KoAAoKiJQZHr3WyUwUi2/omal+sQVmBo
-=dNRa
+iEYEARECAAYFAk5hQQoACgkQsAvGakAaFgCl8QCgzq/I9ekw43H9RWy9xzI1fnJn
+Xd0AoMWfiXi8BeaKvlZonuWrKSytPN/H
+=PcYs
 -----END PGP SIGNATURE-----
diff --git a/media-gfx/gimp/gimp-2.6.11-r4.ebuild b/media-gfx/gimp/gimp-2.6.11-r4.ebuild
new file mode 100644
index 000000000000..0f2589c82957
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.6.11-r4.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.6.11-r4.ebuild,v 1.1 2011/09/02 20:48:14 sping Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit eutils gnome2 fdo-mime multilib python
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.6/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="alsa aalib altivec curl dbus debug doc exif gnome jpeg lcms mmx mng pdf png python smp sse svg tiff webkit wmf"
+
+RDEPEND=">=dev-libs/glib-2.18.1:2
+	>=x11-libs/gtk+-2.12.5:2
+	>=x11-libs/pango-1.18.0
+	x11-libs/libXpm
+	>=media-libs/freetype-2.1.7
+	>=media-libs/fontconfig-2.2.0
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-misc/xdg-utils
+	x11-themes/hicolor-icon-theme
+	>=media-libs/gegl-0.0.22
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	gnome? ( gnome-base/gvfs )
+	webkit? ( net-libs/webkit-gtk:2 )
+	jpeg? ( virtual/jpeg:0 )
+	exif? ( >=media-libs/libexif-0.6.15 )
+	lcms? ( =media-libs/lcms-1* )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-0.12.3-r3[cairo] )
+	png? ( >=media-libs/libpng-1.2.2:0 )
+	python?	( >=dev-python/pygtk-2.10.4:2 )
+	tiff? ( >=media-libs/tiff-3.5.7 )
+	svg? ( >=gnome-base/librsvg-2.8.0:2 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.12.0
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+pkg_setup() {
+	G2CONF="--enable-default-binary \
+		--with-x \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with curl libcurl) \
+		$(use_with dbus) \
+		--without-hal \
+		$(use_with gnome gvfs) \
+		--without-gnomevfs \
+		$(use_with webkit) \
+		$(use_with jpeg libjpeg) \
+		$(use_with exif libexif) \
+		$(use_with lcms) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with wmf)"
+
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# security fixes from upstream, see
+	# https://bugzilla.gnome.org/show_bug.cgi?id=639203
+	epatch "${FILESDIR}"/gimp-CVE-2010-4540-to-4543.diff
+
+	# fixes for libpng 1.5 (incomplete), see
+	# https://bugzilla.gnome.org/show_bug.cgi?id=640409
+	epatch "${FILESDIR}"/gimp-libpng15-v2.diff
+
+	# don't use empty, removed header
+	# https://bugs.gentoo.org/show_bug.cgi?id=377075
+	epatch "${FILESDIR}"/gimp-curl-headers.diff
+
+	# apply file-uri patch by upstream
+	# https://bugs.gentoo.org/show_bug.cgi?id=372941
+	# https://bugzilla.gnome.org/show_bug.cgi?id=653980#c6
+	epatch "${FILESDIR}"/${P}-file-uri.patch
+
+	echo '#!/bin/sh' > py-compile
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_convert_shebangs -r $(python_get_version) "${ED}"
+		python_need_rebuild
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
diff --git a/media-gfx/gimp/gimp-2.7.3-r1.ebuild b/media-gfx/gimp/gimp-2.7.3-r1.ebuild
new file mode 100644
index 000000000000..7ed812eabf65
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.7.3-r1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.7.3-r1.ebuild,v 1.1 2011/09/02 20:48:14 sping Exp $
+
+EAPI="3"
+PYTHON_DEPEND="python? 2:2.5"
+
+inherit versionator autotools eutils gnome2 fdo-mime multilib python
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="alsa aalib altivec curl dbus debug doc exif gnome jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
+
+RDEPEND=">=dev-libs/glib-2.28.1:2
+	>=x11-libs/gtk+-2.24.3:2
+	>=x11-libs/gdk-pixbuf-2.22.1:2
+	>=x11-libs/cairo-1.10.2
+	>=x11-libs/pango-1.22.0
+	xpm? ( x11-libs/libXpm )
+	>=media-libs/freetype-2.1.7
+	>=media-libs/fontconfig-2.2.0
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-misc/xdg-utils
+	x11-themes/hicolor-icon-theme
+	>=media-libs/babl-0.1.4
+	>=media-libs/gegl-0.1.6
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	gnome? ( gnome-base/gvfs )
+	webkit? ( net-libs/webkit-gtk:2 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper )
+	exif? ( >=media-libs/libexif-0.6.15 )
+	lcms? ( >=media-libs/lcms-1.16:0 )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-0.12.4[cairo] )
+	png? ( >=media-libs/libpng-1.2.37:0 )
+	python?	( >=dev-python/pygtk-2.10.4:2 )
+	tiff? ( >=media-libs/tiff-3.5.7 )
+	svg? ( >=gnome-base/librsvg-2.14.0:2 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	x11-libs/libXcursor
+	udev? ( sys-fs/udev[gudev] )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.22
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.17
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+pkg_setup() {
+	G2CONF="--enable-default-binary \
+		--with-x \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with curl libcurl) \
+		$(use_with dbus) \
+		$(use_with gnome gvfs) \
+		$(use_with webkit) \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k libjasper) \
+		$(use_with exif libexif) \
+		$(use_with lcms) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with udev gudev) \
+		$(use_with wmf) \
+		--with-xmc \
+		$(use_with xpm libxpm) \
+		--without-xvfb-run"
+
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-glib-2.29.patch
+	eautoreconf
+
+	echo '#!/bin/sh' > py-compile
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_convert_shebangs -r $(python_get_version) "${ED}"
+		python_need_rebuild
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+
+	use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
+		/usr/$(get_libdir)/gimp/2.0/plug-ins
+}