Version bump, bug 308721

Package-Manager: portage-2.2_rc66/cvs/Linux x86_64

4 files changed, 142 insertions, 2 deletions

diff --git a/dev-util/kdevelop/ChangeLog b/dev-util/kdevelop/ChangeLog
index 47ba45851667..cc3c5bf2e1a9 100644
--- a/dev-util/kdevelop/ChangeLog
+++ b/dev-util/kdevelop/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/kdevelop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.190 2010/02/11 18:40:27 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.191 2010/03/10 14:17:48 reavertm Exp $
+
+*kdevelop-3.9.99 (10 Mar 2010)
+
+  10 Mar 2010; Maciej Mrozowski <reavertm@gentoo.org>
+  +kdevelop-3.9.99.ebuild:
+  Version bump, bug 308721
 
 *kdevelop-3.9.98 (11 Feb 2010)
 
diff --git a/dev-util/kdevelop/kdevelop-3.9.99.ebuild b/dev-util/kdevelop/kdevelop-3.9.99.ebuild
new file mode 100644
index 000000000000..10e5f040c824
--- /dev/null
+++ b/dev-util/kdevelop/kdevelop-3.9.99.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/kdevelop-3.9.99.ebuild,v 1.1 2010/03/10 14:17:48 reavertm Exp $
+
+EAPI="2"
+
+KMNAME="extragear/sdk"
+inherit kde4-base
+
+if [[ ${PV} == *9999* ]]; then
+	KDEVPLATFORM_PV="9999"
+else
+	inherit versionator
+	KDEVPLATFORM_PV="$(($(get_major_version)-3)).$(get_after_major_version)"
+fi
+DESCRIPTION="Integrated Development Environment for Unix, supporting KDE/Qt, C/C++ and many other languages."
+HOMEPAGE="http://www.kdevelop.org/"
+[[ ${PV} != *9999* ]] && SRC_URI="mirror://kde/unstable/${PN}/${PV}/src/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS="~amd64 ~hppa ~x86"
+SLOT="4"
+IUSE="+cmake +cxx debug +qmake qthelp"
+
+DEPEND="
+	>=dev-util/kdevplatform-${KDEVPLATFORM_PV}
+	>=kde-base/ksysguard-${KDE_MINIMAL}
+	>=kde-base/libkworkspace-${KDE_MINIMAL}
+	qthelp? ( >=x11-libs/qt-assistant-4.4:4 )
+"
+RDEPEND="${DEPEND}
+	>=kde-base/kapptemplate-${KDE_MINIMAL}
+	cxx? ( >=sys-devel/gdb-7.0[python] )
+"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Remove this and the ksysguard dep after libprocessui moved into kdelibs
+	sed -i -e 's/${KDE4WORKSPACE_PROCESSUI_LIBS}/processui/g' \
+		debuggers/gdb/CMakeLists.txt \
+		|| die "Failed to patch CMake files"
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build cmake)
+		$(cmake-utils_use_build cmake cmakebuilder)
+		$(cmake-utils_use_build qmake)
+		$(cmake-utils_use_build qmake qmakebuilder)
+		$(cmake-utils_use_build qmake qmake_parser)
+		$(cmake-utils_use_build cxx cpp)
+		$(cmake-utils_use_build qthelp)
+	)
+
+	kde4-base_src_configure
+}
+
+src_install() {
+	kde4-base_src_install
+
+	rm "${D}/${PREFIX}"/share/apps/kdevappwizard/templates/qmake_qt4guiapp.tar.bz2
+	rm "${D}/${PREFIX}"/share/icons/hicolor/22x22/actions/output_win.png
+}
diff --git a/dev-util/kdevplatform/ChangeLog b/dev-util/kdevplatform/ChangeLog
index 8c6712b09c14..3957cc846f8e 100644
--- a/dev-util/kdevplatform/ChangeLog
+++ b/dev-util/kdevplatform/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/kdevplatform
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevplatform/ChangeLog,v 1.20 2010/02/24 13:41:30 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevplatform/ChangeLog,v 1.21 2010/03/10 14:16:56 reavertm Exp $
+
+*kdevplatform-0.9.99 (10 Mar 2010)
+
+  10 Mar 2010; Maciej Mrozowski <reavertm@gentoo.org>
+  +kdevplatform-0.9.99.ebuild:
+  Version bump, bug 308721
 
   24 Feb 2010; Christian Faulhammer <fauli@gentoo.org>
   kdevplatform-0.9.97-r1.ebuild:
diff --git a/dev-util/kdevplatform/kdevplatform-0.9.99.ebuild b/dev-util/kdevplatform/kdevplatform-0.9.99.ebuild
new file mode 100644
index 000000000000..af44c494d31d
--- /dev/null
+++ b/dev-util/kdevplatform/kdevplatform-0.9.99.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevplatform/kdevplatform-0.9.99.ebuild,v 1.1 2010/03/10 14:16:56 reavertm Exp $
+
+EAPI="2"
+
+KMNAME="extragear/sdk"
+inherit kde4-base
+
+if [[ ${PV} == *9999* ]]; then
+	KDEVELOP_PV="9999"
+else
+	inherit versionator
+	KDEVELOP_PV="$(($(get_major_version)+3)).$(get_after_major_version)"
+fi
+DESCRIPTION="KDE development support libraries and apps"
+HOMEPAGE="http://www.kdevelop.org/"
+[[ ${PV} != *9999* ]] && SRC_URI="mirror://kde/unstable/kdevelop/${KDEVELOP_PV}/src/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+SLOT="4"
+# Moved to playground for now
+# bazaar git kompare mercurial
+IUSE="cvs debug subversion"
+
+# Moved to playground for now
+# bazaar? ( dev-vcs/bzr )
+# kompare? ( >=kde-base/kompare-${KDE_MINIMAL} )
+# mercurial? ( dev-vcs/mercurial )
+# git? ( dev-util/git )
+# block - some plugins moved to kdevplatform from kdevelop
+DEPEND="
+	dev-libs/boost
+	cvs? ( dev-util/cvs )
+	subversion? ( >=dev-util/subversion-1.3 )
+"
+RDEPEND="${DEPEND}
+	!<dev-util/kdevelop-${KDEVELOP_PV}
+"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# FindKDevPlatform.cmake is installed by kdelibs
+	sed -i \
+		-e '/cmakeFiles/s/^/#DONOTINSTALL/' \
+		cmake/modules/CMakeLists.txt || die
+}
+
+# Moved to playground for now
+# $(cmake-utils_use_build bazaar)
+# $(cmake-utils_use_build git)
+# $(cmake-utils_use_with kompare)
+# $(cmake-utils_use_build mercurial)
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build cvs)
+		$(cmake-utils_use_build subversion)
+		$(cmake-utils_use_with subversion SubversionLibrary)
+	)
+
+	kde4-base_src_configure
+}