Build and install info pages (bug 287112)

Package-Manager: portage-2.2_rc41/cvs/Linux i686

4 files changed, 419 insertions, 9 deletions

diff --git a/dev-util/git/ChangeLog b/dev-util/git/ChangeLog
index b3cb3b1e54bf..727fbb69e20f 100644
--- a/dev-util/git/ChangeLog
+++ b/dev-util/git/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/git
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.372 2009/10/18 02:02:09 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/ChangeLog,v 1.373 2009/10/22 20:00:36 sping Exp $
+
+*git-1.6.5.1-r1 (22 Oct 2009)
+
+  22 Oct 2009; Sebastian Pipping <sping@gentoo.org> +git-1.6.5.1-r1.ebuild,
+  git-9999.ebuild:
+  Build and install info pages (bug 287112), add dependency on texinfo, drop
+  keywords: alpha arm ia64 ppc64
 
 *git-1.6.5.1 (18 Oct 2009)
 
diff --git a/dev-util/git/Manifest b/dev-util/git/Manifest
index 6a164648c7c9..572031723ba4 100644
--- a/dev-util/git/Manifest
+++ b/dev-util/git/Manifest
@@ -46,10 +46,11 @@ EBUILD git-1.6.4.2.ebuild 9821 RMD160 f15a4f0f08995c626b629339c5dc58ed32434e0c S
 EBUILD git-1.6.4.3.ebuild 9821 RMD160 af24b1ba074d9057a8f5e599404f31b50f49b5fd SHA1 f93074849d2bb74ce909d9b82660012367b26fbc SHA256 1edaf7a0d525436a516bfc2dca0701575c283a8fd947fd9e7a9eb17078af553e
 EBUILD git-1.6.4.4.ebuild 9811 RMD160 c0780fdf55763b2d6de60daf9ea1808d2aad16b3 SHA1 9c16fdf4e691f341aebf3a62c2fd7c4ead8da062 SHA256 b3d51ba85fd2a60cae86a9733a0e27255e2b45a763efbac7a3a87b13552ca3d2
 EBUILD git-1.6.4.ebuild 9819 RMD160 de1cf8f5663fbab2bb375df1e2cd3bb2b52f198b SHA1 0e8a42316f6208afc2945372931aff2b27bd965f SHA256 ac21060922927b8416e9322b8465abc547fd75ec884a61176a3833c6b46f6338
+EBUILD git-1.6.5.1-r1.ebuild 10439 RMD160 da4b07eea36e367bb07912bede13a995bc1ed013 SHA1 b180e0dfc1533afae8f17f1c86270f1bcb95cf6b SHA256 ab74bc4fbe1a51cc8e97318ea2b10380b22b12c7926ecc2736b2a549f6a0f14d
 EBUILD git-1.6.5.1.ebuild 10168 RMD160 88b3bf9a825f2747d6bf5e00453e4767418ef938 SHA1 c338dea641ed782111c24341e56546e65be77d6e SHA256 38dacbe31209f19df1caef00b44549bf3209739c6703843a71dffcd68a4848bb
 EBUILD git-1.6.5.ebuild 10166 RMD160 9bcc1577d0b38e77213c116c0613a95ff0ff4cce SHA1 fdf93b802abbc2d3b55e67fe4d6c6b534e2785c2 SHA256 badc2c40eae8c1e374f5d8e89541cfd23596975d7d965c74dabc4c44cbdfdcc4
 EBUILD git-1.6.5_rc1.ebuild 9823 RMD160 40a2e88febb5674a6f79ac382e8cd94f4a4930b9 SHA1 8c3262bf66824db6705044a4ef50dfbab3304ed7 SHA256 518ac6c3ebbcea01f28193899656af708b1ec59988129415adef42c80850f90d
 EBUILD git-1.6.5_rc2.ebuild 9839 RMD160 5af2b096f748f2dc3a3176eeda04083756509653 SHA1 c43a3ea0e626f903692688442a2a46b8304d9773 SHA256 f14799b5bdad4fb565fd64f782189489dedf29d778f6d8969ce75267f59ea5ea
-EBUILD git-9999.ebuild 10166 RMD160 20455e5779020e00b966b49acb59f42da7301b76 SHA1 523efde94fdbabd41fc89a0286679fe9435629e3 SHA256 5fe02526fec50db0662ade16f11e3bd88c0adef72e455d542db1e15da6a34a96
-MISC ChangeLog 57324 RMD160 3179f46a02ace5156e4377f0d987a8c2550d73f6 SHA1 467a454738f34145534c984532132bc66955973e SHA256 d32d41714a75f3859c14a245fc26d2d2f4daabc00a3dc931fac40dc818349f1e
+EBUILD git-9999.ebuild 10459 RMD160 3747855f0585d6097aaabfd7006d47519fd4ae73 SHA1 e8e50bf7bdfab7802ba15a2b23810d7cb90abee2 SHA256 6317c12aca3ddc6e4cf861c11f69ddb5785b7ee5056b59ff3a55be7be5b65e09
+MISC ChangeLog 57559 RMD160 20886a794600b45370166db46b454ca15db734ff SHA1 dc812bd9cc9e9f9a690e7c7f68cf6a0313ab9955 SHA256 e16bed7463ddf731e3f336a3c10faa0c80602349068ab42ad9f9cb015f65aa35
 MISC metadata.xml 1610 RMD160 6b03b898986d26bba7ff441dc1c8c9ec04a9a2b9 SHA1 a0a0d304138c648729d225954de89c1aac359008 SHA256 d070dc8e46e0fd44676d0491353f95385e65c1ffcd1313193dc59d495245c007
diff --git a/dev-util/git/git-1.6.5.1-r1.ebuild b/dev-util/git/git-1.6.5.1-r1.ebuild
new file mode 100644
index 000000000000..32d2fe9104ae
--- /dev/null
+++ b/dev-util/git/git-1.6.5.1-r1.ebuild
@@ -0,0 +1,390 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-1.6.5.1-r1.ebuild,v 1.1 2009/10/22 20:00:36 sping Exp $
+
+EAPI=2
+
+inherit toolchain-funcs eutils elisp-common perl-module bash-completion
+[ "$PV" == "9999" ] && inherit git
+
+MY_PV="${PV/_rc/.rc}"
+MY_P="${PN}-${MY_PV}"
+
+DOC_VER=${MY_PV}
+
+DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
+HOMEPAGE="http://www.git-scm.com/"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
+			mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
+			doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
+	KEYWORDS="~amd64 ~hppa ~mips ~ppc ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+else
+	SRC_URI=""
+	EGIT_BRANCH="master"
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/git/git.git"
+	# EGIT_REPO_URI="http://www.kernel.org/pub/scm/git/git.git"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+blksha1 +curl cgi +doc emacs gtk iconv +perl ppcsha1 tk +threads +webdav xinetd cvs subversion"
+
+# Common to both DEPEND and RDEPEND
+CDEPEND="
+	!app-misc/git
+	!blksha1? ( dev-libs/openssl )
+	sys-libs/zlib
+	app-arch/cpio
+	perl?   ( dev-lang/perl )
+	tk?     ( dev-lang/tk )
+	curl?   (
+		net-misc/curl
+		webdav? ( dev-libs/expat )
+	)
+	emacs?  ( virtual/emacs )"
+
+RDEPEND="${CDEPEND}
+	perl? ( dev-perl/Error
+			dev-perl/Net-SMTP-SSL
+			dev-perl/Authen-SASL
+			cgi? ( virtual/perl-CGI )
+			cvs? ( >=dev-util/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
+			subversion? ( dev-util/subversion[-dso] dev-perl/libwww-perl dev-perl/TermReadKey )
+			)
+	gtk?
+	(
+		>=dev-python/pygtk-2.8
+		|| ( dev-python/pygtksourceview:2  dev-python/gtksourceview-python )
+	)"
+
+# This is how info docs are created with Git:
+#   .txt/asciidoc --(asciidoc)---------> .xml/docbook
+#   .xml/docbook  --(docbook2texi.pl)--> .texi
+#   .texi         --(makeinfo)---------> .info
+DEPEND="${CDEPEND}
+	doc?    (
+		app-text/asciidoc
+		app-text/docbook2X
+		sys-apps/texinfo
+	)"
+
+# Live ebuild builds HTML docs, additionally
+if [ "$PV" == "9999" ]; then
+	DEPEND="${DEPEND}
+		doc?    (
+			app-text/xmlto
+		)"
+fi
+
+SITEFILE=50${PN}-gentoo.el
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if ! use perl ; then
+		use cgi && ewarn "gitweb needs USE=perl, ignoring USE=cgi"
+		use cvs && ewarn "CVS integration needs USE=perl, ignoring USE=cvs"
+		use subversion && ewarn "git-svn needs USE=perl, it won't work"
+	fi
+	if use webdav && ! use curl ; then
+		ewarn "USE=webdav needs USE=curl. Ignoring"
+	fi
+	if use subversion && has_version dev-util/subversion && built_with_use --missing false dev-util/subversion dso ; then
+		ewarn "Per Gentoo bugs #223747, #238586, when subversion is built"
+		ewarn "with USE=dso, there may be weird crashes in git-svn. You"
+		ewarn "have been warned."
+	fi
+}
+
+# This is needed because for some obscure reasons future calls to make don't
+# pick up these exports if we export them in src_unpack()
+exportmakeopts() {
+	local myopts
+
+	if use blksha1 ; then
+		myopts="${myopts} BLK_SHA1=YesPlease"
+	elif use ppcsha1 ; then
+		myopts="${myopts} PPC_SHA1=YesPlease"
+	fi
+
+	if use curl ; then
+		use webdav || myopts="${myopts} NO_EXPAT=YesPlease"
+	else
+		myopts="${myopts} NO_CURL=YesPlease"
+	fi
+
+	use iconv \
+		|| myopts="${myopts} NO_ICONV=YesPlease"
+	use tk \
+		|| myopts="${myopts} NO_TCLTK=YesPlease"
+	use perl \
+		&& myopts="${myopts} INSTALLDIRS=vendor" \
+		|| myopts="${myopts} NO_PERL=YesPlease"
+	use threads \
+		&& myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
+	use subversion \
+		|| myopts="${myopts} NO_SVN_TESTS=YesPlease"
+
+	has_version '>=app-text/asciidoc-8.0' \
+		&& myopts="${myopts} ASCIIDOC8=YesPlease"
+	myopts="${myopts} ASCIIDOC_NO_ROFF=YesPlease"
+
+	export MY_MAKEOPTS="${myopts}"
+}
+
+src_unpack() {
+	if [ "${PV}" != "9999" ]; then
+		unpack ${MY_P}.tar.bz2
+		cd "${S}"
+		unpack ${PN}-manpages-${DOC_VER}.tar.bz2
+		use doc && \
+			cd "${S}"/Documentation && \
+			unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
+		cd "${S}"
+	else
+		git_src_unpack
+		cd "${S}"
+		#cp "${FILESDIR}"/GIT-VERSION-GEN .
+	fi
+
+}
+
+src_prepare() {
+	# Noperl is being merged to upstream as of 2009/04/05
+	#epatch "${FILESDIR}"/20090305-git-1.6.2-noperl.patch
+
+	# GetOpt-Long v2.38 is strict
+	# Merged in 1.6.3 final 2009/05/07
+	#epatch "${FILESDIR}"/20090505-git-1.6.2.5-getopt-fixes.patch
+
+	sed -i \
+		-e 's:^\(CFLAGS =\).*$:\1 $(OPTCFLAGS) -Wall:' \
+		-e 's:^\(LDFLAGS =\).*$:\1 $(OPTLDFLAGS):' \
+		-e 's:^\(CC = \).*$:\1$(OPTCC):' \
+		-e 's:^\(AR = \).*$:\1$(OPTAR):' \
+		Makefile || die "sed failed"
+
+	# Fix docbook2texi command
+	sed -i 's/DOCBOOK2X_TEXI=docbook2x-texi/DOCBOOK2X_TEXI=docbook2texi.pl/' \
+		Documentation/Makefile || die "sed failed"
+}
+
+git_emake() {
+	emake ${MY_MAKEOPTS} \
+		DESTDIR="${D}" \
+		OPTCFLAGS="${CFLAGS}" \
+		OPTLDFLAGS="${LDFLAGS}" \
+		OPTCC="$(tc-getCC)" \
+		OPTAR="$(tc-getAR)" \
+		prefix=/usr \
+		htmldir=/usr/share/doc/${PF}/html \
+		"$@"
+}
+
+src_configure() {
+	exportmakeopts
+}
+
+src_compile() {
+	git_emake || die "emake failed"
+
+	if use emacs ; then
+		elisp-compile contrib/emacs/git{,-blame}.el \
+			|| die "emacs modules failed"
+	fi
+
+	if use perl && use cgi ; then
+		git_emake \
+			gitweb/gitweb.cgi \
+			|| die "emake gitweb/gitweb.cgi failed"
+	fi
+
+	cd "${S}"/Documentation
+	if [[ "$PV" == "9999" ]] ; then
+		git_emake man \
+			|| die "emake man failed"
+		if use doc ; then
+			git_emake info html \
+				|| die "emake info html failed"
+		fi
+	else
+		if use doc ; then
+			git_emake info \
+				|| die "emake info html failed"
+		fi
+	fi
+}
+
+src_install() {
+	git_emake \
+		install || \
+		die "make install failed"
+
+	doman man?/*.[157] Documentation/*.[157]
+
+	dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
+	use doc && dodir /usr/share/doc/${PF}/html
+	for d in / /howto/ /technical/ ; do
+		docinto ${d}
+		dodoc Documentation${d}*.txt
+		use doc && dohtml -p ${d} Documentation${d}*.html
+	done
+	docinto /
+	# Upstream does not ship this pre-built :-(
+	use doc && doinfo Documentation/{git,gitman}.info
+
+	dobashcompletion contrib/completion/git-completion.bash ${PN}
+
+	if use emacs ; then
+		elisp-install ${PN} contrib/emacs/git.{el,elc} || die
+		elisp-install ${PN} contrib/emacs/git-blame.{el,elc} || die
+		#elisp-install ${PN}/compat contrib/emacs/vc-git.{el,elc} || die
+		# don't add automatically to the load-path, so the sitefile
+		# can do a conditional loading
+		touch "${D}${SITELISP}/${PN}/compat/.nosearch"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+	fi
+
+	if use gtk ; then
+		dobin "${S}"/contrib/gitview/gitview
+		dodoc "${S}"/contrib/gitview/gitview.txt
+	fi
+
+	dobin contrib/fast-import/git-p4
+	dodoc contrib/fast-import/git-p4.txt
+	newbin contrib/fast-import/import-tars.perl import-tars
+
+	dodir /usr/share/${PN}/contrib
+	# The following are excluded:
+	# svnimport - use git-svn
+	# p4import - excluded because fast-import has a better one
+	# examples - these are stuff that is not used in Git anymore actually
+	# patches - stuff the Git guys made to go upstream to other places
+	for i in continuous fast-import hg-to-git \
+		hooks remotes2config.sh stats \
+		workdir convert-objects blameview ; do
+		cp -rf \
+			"${S}"/contrib/${i} \
+			"${D}"/usr/share/${PN}/contrib \
+			|| die "Failed contrib ${i}"
+	done
+
+	if use perl && use cgi ; then
+		dodir /usr/share/${PN}/gitweb
+		insinto /usr/share/${PN}/gitweb
+		doins "${S}"/gitweb/gitweb.cgi
+		doins "${S}"/gitweb/gitweb.css
+		doins "${S}"/gitweb/git-{favicon,logo}.png
+
+		# Make sure it can run
+		fperms 0755 /usr/share/${PN}/gitweb/gitweb.cgi
+
+		# INSTALL discusses configuration issues, not just installation
+		docinto /
+		newdoc  "${S}"/gitweb/INSTALL INSTALL.gitweb
+		newdoc  "${S}"/gitweb/README README.gitweb
+
+		find "${D}"/usr/lib64/perl5/ \
+			-name .packlist \
+			-exec rm \{\} \;
+	fi
+	if ! use subversion ; then
+		rm -f "${D}"/usr/libexec/git-core/git-svn \
+			"${D}"/usr/share/man/man1/git-svn.1*
+	fi
+
+	if use xinetd ; then
+		insinto /etc/xinetd.d
+		newins "${FILESDIR}"/git-daemon.xinetd git-daemon
+	fi
+
+	newinitd "${FILESDIR}"/git-daemon.initd git-daemon
+	newconfd "${FILESDIR}"/git-daemon.confd git-daemon
+
+	fixlocalpod
+}
+
+src_test() {
+	local disabled=""
+	local tests_cvs="t9200-git-cvsexportcommit.sh \
+					t9400-git-cvsserver-server.sh \
+					t9600-cvsimport.sh"
+	local tests_perl="t5502-quickfetch.sh \
+					t5512-ls-remote.sh \
+					t5520-pull.sh"
+
+	# Unzip is used only for the testcase code, not by any normal parts of Git.
+	if ! has_version app-arch/unzip ; then
+		einfo "Disabling tar-tree tests"
+		disabled="${disabled} t5000-tar-tree.sh"
+	fi
+
+	cvs=0
+	use cvs && let cvs=$cvs+1
+	if [[ ${EUID} -eq 0 ]]; then
+		if [[ $cvs -eq 1 ]]; then
+			ewarn "Skipping CVS tests because CVS does not work as root!"
+			ewarn "You should retest with FEATURES=userpriv!"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+		# Bug #225601 - t0004 is not suitable for root perm
+		# Bug #219839 - t1004 is not suitable for root perm
+		disabled="${disabled} t0004-unwritable.sh t1004-read-tree-m-u-wf.sh"
+	else
+		[[ $cvs -gt 0 ]] && \
+			has_version dev-util/cvs && \
+			let cvs=$cvs+1
+		[[ $cvs -gt 1 ]] && \
+			built_with_use dev-util/cvs server && \
+			let cvs=$cvs+1
+		if [[ $cvs -lt 3 ]]; then
+			einfo "Disabling CVS tests (needs dev-util/cvs[USE=server])"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+	fi
+
+	if ! use perl ; then
+		einfo "Disabling tests that need Perl"
+		disabled="${disabled} ${tests_perl}"
+	fi
+
+	# Reset all previously disabled tests
+	cd "${S}/t"
+	for i in *.sh.DISABLED ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
+	done
+	einfo "Disabled tests:"
+	for i in ${disabled} ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
+	done
+	cd "${S}"
+	# Now run the tests
+	einfo "Start test run"
+	git_emake \
+		test || die "tests failed"
+}
+
+showpkgdeps() {
+	local pkg=$1
+	shift
+	elog "  $(printf "%-17s:" ${pkg}) ${@}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+	if use subversion && has_version dev-util/subversion && ! built_with_use --missing false dev-util/subversion perl ; then
+		ewarn "You must build dev-util/subversion with USE=perl"
+		ewarn "to get the full functionality of git-svn!"
+	fi
+	elog "These additional scripts need some dependencies:"
+	echo
+	showpkgdeps git-quiltimport "dev-util/quilt"
+	showpkgdeps git-instaweb \
+		"|| ( www-servers/lighttpd www-servers/apache )"
+	echo
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}
diff --git a/dev-util/git/git-9999.ebuild b/dev-util/git/git-9999.ebuild
index b757f75ddbda..200097b5cfef 100644
--- a/dev-util/git/git-9999.ebuild
+++ b/dev-util/git/git-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-9999.ebuild,v 1.14 2009/10/11 22:28:17 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/git/git-9999.ebuild,v 1.15 2009/10/22 20:00:36 sping Exp $
 
 EAPI=2
 
@@ -59,15 +59,22 @@ RDEPEND="${CDEPEND}
 		|| ( dev-python/pygtksourceview:2  dev-python/gtksourceview-python )
 	)"
 
-DEPEND="${CDEPEND}"
+# This is how info docs are created with Git:
+#   .txt/asciidoc --(asciidoc)---------> .xml/docbook
+#   .xml/docbook  --(docbook2texi.pl)--> .texi
+#   .texi         --(makeinfo)---------> .info
+DEPEND="${CDEPEND}
+	doc?    (
+		app-text/asciidoc
+		app-text/docbook2X
+		sys-apps/texinfo
+	)"
 
-# These are needed to build the docs
+# Live ebuild builds HTML docs, additionally
 if [ "$PV" == "9999" ]; then
 	DEPEND="${DEPEND}
 		doc?    (
-			app-text/asciidoc
 			app-text/xmlto
-			app-text/docbook2X
 		)"
 fi
 
@@ -201,6 +208,11 @@ src_compile() {
 			git_emake info html \
 				|| die "emake info html failed"
 		fi
+	else
+		if use doc ; then
+			git_emake info \
+				|| die "emake info html failed"
+		fi
 	fi
 }
 
@@ -220,7 +232,7 @@ src_install() {
 	done
 	docinto /
 	# Upstream does not ship this pre-built :-(
-	[[ "$PV" == "9999" ]] && use doc && doinfo Documentation/{git,gitman}.info
+	use doc && doinfo Documentation/{git,gitman}.info
 
 	dobashcompletion contrib/completion/git-completion.bash ${PN}