Version bump.

Package-Manager: portage-2.2.0_alpha12_p8/cvs/Linux x86_64

3 files changed, 194 insertions, 1 deletions

diff --git a/dev-util/eric/ChangeLog b/dev-util/eric/ChangeLog
index 585b6e214521..a3e0e4f3f3de 100644
--- a/dev-util/eric/ChangeLog
+++ b/dev-util/eric/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/eric
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.145 2011/01/04 21:44:00 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/ChangeLog,v 1.146 2011/01/04 21:48:22 arfrever Exp $
+
+*eric-5.0.5 (04 Jan 2011)
+
+  04 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +eric-5.0.5.ebuild:
+  Version bump.
 
 *eric-4.4.11 (04 Jan 2011)
 
diff --git a/dev-util/eric/eric-4.4.11.ebuild b/dev-util/eric/eric-4.4.11.ebuild
new file mode 100644
index 000000000000..ebbca6ab0887
--- /dev/null
+++ b/dev-util/eric/eric-4.4.11.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-4.4.11.ebuild,v 1.1 2011/01/04 21:44:00 arfrever Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.6"
+SUPPORT_PYTHON_ABIS="1"
+# 2.4 and 2.5 are restricted to avoid conditional dependency on dev-python/simplejson.
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.* *-jython"
+
+inherit eutils python
+
+MY_PN="${PN}${PV%%.*}"
+MY_PV="${PV/_pre/-snapshot-}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
+SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="4"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="kde spell"
+
+DEPEND="dev-python/PyQt4[assistant,svg,webkit,X]
+	dev-python/qscintilla-python
+	kde? ( kde-base/pykde4 )"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.0
+	dev-python/coverage
+	>=dev-python/pygments-1.1"
+PDEPEND="spell? ( dev-python/pyenchant )"
+
+LANGS="cs de es fr it ru tr zh_CN"
+for L in ${LANGS}; do
+	SRC_URI="${SRC_URI}
+		linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
+	IUSE="${IUSE} linguas_${L}"
+done
+unset L
+
+S="${WORKDIR}/${MY_P}"
+
+PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
+
+src_prepare() {
+	epatch "${FILESDIR}/eric-4.4-no-interactive.patch"
+	epatch "${FILESDIR}/remove_coverage.patch"
+	use kde || epatch "${FILESDIR}/eric-4.4-no-pykde.patch"
+
+	# Delete internal copies of dev-python/chardet, dev-python/coverage, dev-python/pygments and dev-python/simplejson.
+	rm -fr eric/ThirdParty
+	rm -fr eric/DebugClients/Python{,3}/coverage
+}
+
+src_install() {
+	installation() {
+		"$(PYTHON)" install.py \
+			-z \
+			-b "${EPREFIX}/usr/bin" \
+			-i "${T}/images/${PYTHON_ABI}" \
+			-d "${EPREFIX}$(python_get_sitedir)" \
+			-c
+	}
+	python_execute_function installation
+	python_merge_intermediate_installation_images "${T}/images"
+
+	doicon eric/icons/default/eric.png || die "doicon failed"
+	make_desktop_entry "${MY_PN} --nosplash" ${MY_PN} eric "Development;IDE;Qt"
+}
+
+pkg_postinst() {
+	python_mod_optimize ${MY_PN}{,config.py,plugins}
+
+	elog
+	elog "If you want to use Eric with mod_python, have a look at"
+	elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
+	elog
+	elog "The following packages will give Eric extended functionality:"
+	elog "  dev-python/pylint"
+	elog "  dev-python/pysvn"
+	elog
+	elog "This version has a plugin interface with plugin-autofetch from"
+	elog "the application itself. You may want to check those as well."
+	elog
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${MY_PN}{,config.py,plugins}
+}
diff --git a/dev-util/eric/eric-5.0.5.ebuild b/dev-util/eric/eric-5.0.5.ebuild
new file mode 100644
index 000000000000..f10b5c90e35b
--- /dev/null
+++ b/dev-util/eric/eric-5.0.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/eric/eric-5.0.5.ebuild,v 1.1 2011/01/04 21:48:22 arfrever Exp $
+
+EAPI="3"
+PYTHON_DEPEND="3"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.* *-jython"
+
+inherit eutils python
+
+MY_PN="${PN}${PV%%.*}"
+MY_PV="${PV/_pre/-snapshot-}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="A full featured Python IDE using PyQt4 and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+BASE_URI="mirror://sourceforge/eric-ide/${MY_PN}/stable/${PV}"
+SRC_URI="${BASE_URI}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="spell"
+
+DEPEND=">=dev-python/PyQt4-4.7[assistant,svg,webkit,X]
+	>=dev-python/qscintilla-python-2.4"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-2.0.1
+	>=dev-python/coverage-3.2
+	>=dev-python/pygments-1.1.1"
+PDEPEND="spell? ( dev-python/pyenchant )"
+
+LANGS="cs de es it ru"
+for L in ${LANGS}; do
+	SRC_URI="${SRC_URI}
+		linguas_${L}? ( ${BASE_URI}/${MY_PN}-i18n-${L/zh_CN/zh_CN.GB2312}-${MY_PV}.tar.gz )"
+	IUSE="${IUSE} linguas_${L}"
+done
+unset L
+
+S="${WORKDIR}/${MY_P}"
+
+PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/.*")
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-5.0.2-remove_coverage.patch"
+
+	# Avoid file collisions between different slots of Eric.
+	sed -e "s/^Icon=eric$/&${SLOT}/" -i eric/${MY_PN}.desktop || die "sed failed"
+	sed -e "s/\([^[:alnum:]]\)eric\.png\([^[:alnum:]]\)/\1eric5.png\2/" -i $(grep -lr eric.png .) || die "sed failed"
+	mv eric/icons/default/eric{,5}.png || die "mv failed"
+	mv eric/pixmaps/eric{,5}.png || die "mv failed"
+	rm -f eric/APIs/Python/zope-*.api
+	rm -f eric/APIs/Ruby/Ruby-*.api
+
+	# Delete internal copies of dev-python/chardet, dev-python/coverage and dev-python/pygments.
+	rm -fr eric/ThirdParty
+	rm -fr eric/DebugClients/Python{,3}/coverage
+}
+
+src_install() {
+	installation() {
+		"$(PYTHON)" install.py \
+			-z \
+			-b "${EPREFIX}/usr/bin" \
+			-i "${T}/images/${PYTHON_ABI}" \
+			-d "${EPREFIX}$(python_get_sitedir)" \
+			-c
+	}
+	python_execute_function installation
+	python_merge_intermediate_installation_images "${T}/images"
+
+	doicon eric/icons/default/${MY_PN}.png || die "doicon failed"
+}
+
+pkg_postinst() {
+	python_mod_optimize -x "/eric5/DebugClients/Python/" ${MY_PN}{,config.py,plugins}
+
+	elog
+	elog "If you want to use Eric with mod_python, have a look at"
+	elog "\"${EROOT}$(python_get_sitedir -b -f)/${MY_PN}/patch_modpython.py\"."
+	elog
+	elog "The following packages will give Eric extended functionality:"
+	elog "  dev-python/pylint"
+	elog "  dev-python/pysvn"
+	elog
+	elog "This version has a plugin interface with plugin-autofetch from"
+	elog "the application itself. You may want to check those as well."
+	elog
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${MY_PN}{,config.py,plugins}
+}