Adding static-libs to IUSE

Package-Manager: portage-2.2_rc52/cvs/Linux x86_64

1 files changed, 65 insertions, 0 deletions

diff --git a/dev-libs/qoauth/qoauth-1.0-r1.ebuild b/dev-libs/qoauth/qoauth-1.0-r1.ebuild
new file mode 100644
index 000000000000..71094d8448f5
--- /dev/null
+++ b/dev-libs/qoauth/qoauth-1.0-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/qoauth/qoauth-1.0-r1.ebuild,v 1.1 2009/11/27 16:38:17 ayoy Exp $
+
+EAPI="2"
+
+inherit qt4
+
+DESCRIPTION="A Qt-based library for OAuth support"
+HOMEPAGE="http://wiki.github.com/ayoy/qoauth"
+SRC_URI="http://files.ayoy.net/qoauth/release/${PV}/src/${P}-src.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc static-libs test"
+
+COMMON_DEPEND="app-crypt/qca:2[debug?]"
+DEPEND="${COMMON_DEPEND}
+	doc? ( app-doc/doxygen )"
+RDEPEND="${COMMON_DEPEND}
+	app-crypt/qca-ossl:2[debug?]"
+
+src_prepare() {
+	qt4_src_prepare
+	sed -i -e '/^ *docs \\$/d' \
+		   -e '/^ *build_all \\$/d' \
+		   -e 's/^\#\(!macx\)/\1/' \
+		   -e "s!\(\$\${INSTALL_PREFIX}\)/lib!\1/$(get_libdir)!" \
+		src/src.pro || die "sed failed"
+
+	# remove _debug suffix - bug 287489
+	sed -i -e '/build_pass/,$d' src/src.pro || die "sed _debug suffix failed"
+
+	sed -i -e "s/\(.*\)lib$/\1$(get_libdir)/" src/pcfile.sh || die "sed failed"
+
+	if ! use test; then
+		sed -i -e 's/^\(SUBDIRS.*\) tests/\1/' ${PN}.pro || die "sed failed"
+	fi
+}
+
+src_configure() {
+	eqmake4
+}
+
+src_compile() {
+	default
+	if use static-libs; then
+		emake -C src static || die "emake failed"
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die "emake install failed"
+	dodoc README CHANGELOG || die "dodoc failed"
+
+	if use static-libs; then
+		dolib.a "${S}/lib/lib${PN}.a" || die "dolib failed"
+	fi
+
+	if use doc; then
+		doxygen "${S}/Doxyfile" || die "Failed to generate documentation"
+		dohtml "${S}"/doc/html/* || die "Failed to install documentation"
+	fi
+}