Conditional patching for kerberos, thanks to Aaron W. Swenson. Fixes #322539

Package-Manager: portage-2.2_rc67/cvs/Linux x86_64

4 files changed, 315 insertions, 2 deletions

diff --git a/dev-db/postgresql-base/ChangeLog b/dev-db/postgresql-base/ChangeLog
index 23ed7604e28f..b3718995ded6 100644
--- a/dev-db/postgresql-base/ChangeLog
+++ b/dev-db/postgresql-base/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-db/postgresql-base
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.55 2010/06/13 20:32:31 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.56 2010/06/15 20:36:40 patrick Exp $
+
+*postgresql-base-9.0_beta2-r1 (15 Jun 2010)
+*postgresql-base-8.4.4-r2 (15 Jun 2010)
+
+  15 Jun 2010; Patrick Lauer <patrick@gentoo.org>
+  +postgresql-base-8.4.4-r2.ebuild, +postgresql-base-9.0_beta2-r1.ebuild:
+  Conditional patching for kerberos, thanks to Aaron W. Swenson. Fixes
+  #322539
 
   13 Jun 2010; Pawel Hajdan jr <phajdan.jr@gentoo.org>
   postgresql-base-7.4.29.ebuild, postgresql-base-8.0.25.ebuild,
diff --git a/dev-db/postgresql-base/Manifest b/dev-db/postgresql-base/Manifest
index 6908dad9bcd8..0360879d6f25 100644
--- a/dev-db/postgresql-base/Manifest
+++ b/dev-db/postgresql-base/Manifest
@@ -84,10 +84,12 @@ EBUILD postgresql-base-8.4.2-r1.ebuild 4655 RMD160 816a9994a9103f76e8e6126aae20d
 EBUILD postgresql-base-8.4.2.ebuild 4652 RMD160 af60b1a04ccc310d14cad1e821289f1b7b99eba2 SHA1 1729294daa83e30a4817aee2a3426c0075e2ae47 SHA256 5713b8236cca52b3a8f552df8452fed69d224b34c465813d7b5fbc1fa5dfc942
 EBUILD postgresql-base-8.4.3.ebuild 4635 RMD160 853a7af30e0a7931c13366f048ecd52f920cdbbb SHA1 88a534eb0ca96895360b983dbc32a2c00c874670 SHA256 49be0b76d6243ef9fad7a0ab8c05bb06707b3a745494b34db2d2ab33869ff98f
 EBUILD postgresql-base-8.4.4-r1.ebuild 4650 RMD160 ec73101f9f846852700c8e5d74e7d681273b3a47 SHA1 d80be65fc7554d86939abd0a44ce5a242ada8f32 SHA256 3954f82545772a28529b1438bb76e21b97c55ca761ae69628bccf6bd967ef2ed
+EBUILD postgresql-base-8.4.4-r2.ebuild 4729 RMD160 318c9609c883ca926ed41e9c0441b01dc92a4e07 SHA1 858306f343697a9327602dd9bed83d29c03b09ef SHA256 266f81023d69d4b59d3825251ff5c98de88abbe423632a6dd3f3a59f0748065c
 EBUILD postgresql-base-8.4.4.ebuild 4637 RMD160 5e6bc1d946ac024a5b20c7dec931001c99b0c7c9 SHA1 5a1a2c95a91c2c725520b8271d5719642ae899ce SHA256 dce83cbcf22d6d1bf131c816c6865631ca443bc767162dbd4aca16d8f63eacd8
 EBUILD postgresql-base-9.0_alpha4.ebuild 4676 RMD160 8f89109d20dd48a0bfbf1e0efe7aea5c499f9bf6 SHA1 21e82137a7c182b0680030235fec2e9b3b5776cd SHA256 dd7904c71b763d5b3285a8f39eb43e7d68daacc26e9f0b1da29597715cc24def
 EBUILD postgresql-base-9.0_beta1-r1.ebuild 4685 RMD160 70bb66ed0c4cbd96ca8de79e20732874bda80ef6 SHA1 c2588a4d2a61f7c72b7b81d2bbd50f7b5121b3fe SHA256 8d6cc182cc35a2435a211d3e1b347b741e235fad21cdc5db77f77f88806e9eaa
 EBUILD postgresql-base-9.0_beta1.ebuild 4626 RMD160 470895df1a27a704ce73b6dd07f8fadacb757d24 SHA1 f5f653ed4ee72080ac6322c785ce21ea40415471 SHA256 572319c583827603f90c1ece1b1e32700a5dfe0f5aaa5021c444e50b84452387
+EBUILD postgresql-base-9.0_beta2-r1.ebuild 4760 RMD160 9dbc316b96d2cc5f7f29d5653470567cc62aa08c SHA1 d5f6ae4f1052080b935fb68e0b773d87a7523713 SHA256 2989b622824586a311cb47827b2fd23160091edf04efc97133dca792626e1614
 EBUILD postgresql-base-9.0_beta2.ebuild 4685 RMD160 671a7c02e2bf37af9a69682ce3987adf48587474 SHA1 73ab40511f2ff26f40748b740b65e3fed3b05d4b SHA256 1f7444f6d3fe96400e33e8bab908f33764b2cbcc7b631b82e0f183151f792563
-MISC ChangeLog 19488 RMD160 50ceae46f9801f8d18e4d0800cd7db5228f539b4 SHA1 48c5da94ded54ba560e17a7dc92b8ab0f3f66a88 SHA256 1d7cb12d6e5e38d6adfb41be71ff7bde2bed80407a13922f1ab89e8971a73713
+MISC ChangeLog 19776 RMD160 353238ede697d5c59c82b6a9a58e6d065312254c SHA1 67188355a8a823a8f846986bad50ac0b3bbd1b1d SHA256 ef23f363554a6aad81447fc96a1638ca0946294320e2aa23a58a35d4fe3a71b4
 MISC metadata.xml 472 RMD160 fe3dc42a49cd1445788d023578d878c6226c72e0 SHA1 f03eda301fc89bf31cfb64bb6cc2cc4ca33cb632 SHA256 ee20753f4083988318c4c30155901e99a800dc8fb19fd77c80f9947c72abbf4c
diff --git a/dev-db/postgresql-base/postgresql-base-8.4.4-r2.ebuild b/dev-db/postgresql-base/postgresql-base-8.4.4-r2.ebuild
new file mode 100644
index 000000000000..35ccb05d4087
--- /dev/null
+++ b/dev-db/postgresql-base/postgresql-base-8.4.4-r2.ebuild
@@ -0,0 +1,151 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.4.4-r2.ebuild,v 1.1 2010/06/15 20:36:40 patrick Exp $
+
+EAPI="2"
+
+WANT_AUTOMAKE="none"
+
+inherit eutils multilib versionator autotools
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+
+DESCRIPTION="PostgreSQL libraries and clients"
+HOMEPAGE="http://www.postgresql.org/"
+SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2"
+LICENSE="POSTGRESQL"
+SLOT="$(get_version_component_range 1-2)"
+IUSE_LINGUAS="
+	linguas_af linguas_cs linguas_de linguas_es linguas_fa linguas_fr
+	linguas_hr linguas_hu linguas_it linguas_ko linguas_nb linguas_pl
+	linguas_pt_BR linguas_ro linguas_ru linguas_sk linguas_sl linguas_sv
+	linguas_tr linguas_zh_CN linguas_zh_TW"
+IUSE="doc kerberos nls pam readline ssl threads zlib ldap pg_legacytimestamp ${IUSE_LINGUAS}"
+RESTRICT="test"
+
+wanted_languages() {
+	for u in ${IUSE_LINGUAS} ; do
+		use $u && echo -n "${u#linguas_} "
+	done
+}
+
+RDEPEND="kerberos? ( virtual/krb5 )
+	pam? ( virtual/pam )
+	readline? ( >=sys-libs/readline-4.1 )
+	ssl? ( >=dev-libs/openssl-0.9.6-r1 )
+	zlib? ( >=sys-libs/zlib-1.1.3 )
+	>=app-admin/eselect-postgresql-0.3
+	virtual/libintl
+	!!dev-db/postgresql-libs
+	!!dev-db/postgresql-client
+	!!dev-db/libpq
+	!!dev-db/postgresql
+	ldap? ( net-nds/openldap )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	>=sys-devel/bison-1.875
+	nls? ( sys-devel/gettext )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+S="${WORKDIR}/postgresql-${PV}"
+
+src_prepare() {
+
+	epatch "${FILESDIR}/postgresql-${SLOT}-common.patch" \
+		"${FILESDIR}/postgresql-${SLOT}-base.patch"
+
+	if use kerberos && has_version "<app-crypt/heimdal-1.3.2-r1" ; then
+		epatch "${FILESDIR}/postgresql-base-8.4-9.0-heimdal_strlcpy.patch"
+	fi
+
+	# to avoid collision - it only should be installed by server
+	rm "${S}/src/backend/nls.mk"
+
+	# because psql/help.c includes the file
+	ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/"
+
+	eautoconf
+}
+
+src_configure() {
+	export LDFLAGS_SL="${LDFLAGS}"
+	econf --prefix=/usr/$(get_libdir)/postgresql-${SLOT} \
+		--datadir=/usr/share/postgresql-${SLOT} \
+		--docdir=/usr/share/doc/postgresql-${SLOT} \
+		--sysconfdir=/etc/postgresql-${SLOT} \
+		--includedir=/usr/include/postgresql-${SLOT} \
+		--mandir=/usr/share/postgresql-${SLOT}/man \
+		--enable-depend \
+		--without-tcl \
+		--without-perl \
+		--without-python \
+		$(use_with readline) \
+		$(use_with kerberos krb5) \
+		$(use_with kerberos gssapi) \
+		"$(use_enable nls nls "$(wanted_languages)")" \
+		$(use_with pam) \
+		$(use_enable !pg_legacytimestamp integer-datetimes ) \
+		$(use_with ssl openssl) \
+		$(use_enable threads thread-safety) \
+		$(use_with zlib) \
+		$(use_with ldap) \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake || die "emake failed"
+
+	cd "${S}/contrib"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	insinto /usr/include/postgresql-${SLOT}/postmaster
+	doins "${S}"/src/include/postmaster/*.h
+	dodir /usr/share/postgresql-${SLOT}/man/man1
+	tar -zxf "${S}/doc/man.tar.gz" -C "${D}"/usr/share/postgresql-${SLOT}/man man1/{ecpg,pg_config}.1
+
+	rm -r "${D}/usr/share/doc/postgresql-${SLOT}/html"
+	rm "${D}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,ipcclean,pg_controldata,pg_ctl,pg_resetxlog,pg_restore,postgres,postmaster}.1
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	cd "${S}/contrib"
+	emake DESTDIR="${D}" install || die "emake install failed"
+	cd "${S}"
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+
+	IDIR="/usr/include/postgresql-${SLOT}"
+	cat > "${D}/etc/eselect/postgresql/slots/${SLOT}/base" <<-__EOF__
+postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+postgres_prefix=/usr/$(get_libdir)/postgresql-${SLOT}
+postgres_datadir=/usr/share/postgresql-${SLOT}
+postgres_bindir=/usr/$(get_libdir)/postgresql-${SLOT}/bin
+postgres_symlinks=(
+	${IDIR} /usr/include/postgresql
+	${IDIR}/libpq-fe.h /usr/include/libpq-fe.h
+	${IDIR}/pg_config_manual.h /usr/include/pg_config_manual.h
+	${IDIR}/libpq /usr/include/libpq
+	${IDIR}/postgres_ext.h /usr/include/postgres_ext.h
+)
+__EOF__
+
+	cat >"${T}/50postgresql-94-${SLOT}" <<-__EOF__
+		LDPATH=/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)
+		MANPATH=/usr/share/postgresql-${SLOT}/man
+	__EOF__
+	doenvd "${T}/50postgresql-94-${SLOT}"
+
+	keepdir /etc/postgresql-${SLOT}
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	elog "If you need a global psqlrc-file, you can place it in '${ROOT}/etc/postgresql-${SLOT}/'."
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}
diff --git a/dev-db/postgresql-base/postgresql-base-9.0_beta2-r1.ebuild b/dev-db/postgresql-base/postgresql-base-9.0_beta2-r1.ebuild
new file mode 100644
index 000000000000..8b567cec61ae
--- /dev/null
+++ b/dev-db/postgresql-base/postgresql-base-9.0_beta2-r1.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.0_beta2-r1.ebuild,v 1.1 2010/06/15 20:36:40 patrick Exp $
+
+EAPI="2"
+
+WANT_AUTOMAKE="none"
+
+inherit eutils multilib versionator autotools
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+
+DESCRIPTION="PostgreSQL libraries and clients"
+HOMEPAGE="http://www.postgresql.org/"
+
+MY_PV=${PV/_/}
+SRC_URI="mirror://postgresql/source/v${MY_PV}/postgresql-${MY_PV}.tar.bz2"
+S=${WORKDIR}/postgresql-${MY_PV}
+
+LICENSE="POSTGRESQL"
+SLOT="$(get_version_component_range 1-2)"
+IUSE_LINGUAS="
+	linguas_af linguas_cs linguas_de linguas_es linguas_fa linguas_fr
+	linguas_hr linguas_hu linguas_it linguas_ko linguas_nb linguas_pl
+	linguas_pt_BR linguas_ro linguas_ru linguas_sk linguas_sl linguas_sv
+	linguas_tr linguas_zh_CN linguas_zh_TW"
+IUSE="doc kerberos nls pam readline ssl threads zlib ldap pg_legacytimestamp ${IUSE_LINGUAS}"
+RESTRICT="test"
+
+wanted_languages() {
+	for u in ${IUSE_LINGUAS} ; do
+		use $u && echo -n "${u#linguas_} "
+	done
+}
+
+RDEPEND="kerberos? ( virtual/krb5 )
+	pam? ( virtual/pam )
+	readline? ( >=sys-libs/readline-4.1 )
+	ssl? ( >=dev-libs/openssl-0.9.6-r1 )
+	zlib? ( >=sys-libs/zlib-1.1.3 )
+	>=app-admin/eselect-postgresql-0.3
+	virtual/libintl
+	!!dev-db/postgresql-libs
+	!!dev-db/postgresql-client
+	!!dev-db/libpq
+	!!dev-db/postgresql
+	ldap? ( net-nds/openldap )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	>=sys-devel/bison-1.875
+	nls? ( sys-devel/gettext )"
+PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
+
+src_prepare() {
+	epatch "${FILESDIR}/postgresql-${SLOT}-common.patch" \
+		"${FILESDIR}/postgresql-${SLOT}-base.2.patch"
+
+	if use kerberos && has_version "<app-crypt/heimdal-1.3.2-r1" ; then
+		"${FILESDIR}/postgresql-base-8.4-9.0-heimdal_strlcpy.patch"
+	fi
+
+	# to avoid collision - it only should be installed by server
+	rm "${S}/src/backend/nls.mk"
+
+	# because psql/help.c includes the file
+	ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/"
+	cd "${S}"
+	eautoconf
+}
+
+src_configure() {
+	export LDFLAGS_SL="${LDFLAGS}"
+	econf --prefix=/usr/$(get_libdir)/postgresql-${SLOT} \
+		--datadir=/usr/share/postgresql-${SLOT} \
+		--docdir=/usr/share/doc/postgresql-${SLOT} \
+		--sysconfdir=/etc/postgresql-${SLOT} \
+		--includedir=/usr/include/postgresql-${SLOT} \
+		--mandir=/usr/share/postgresql-${SLOT}/man \
+		--enable-depend \
+		--without-tcl \
+		--without-perl \
+		--without-python \
+		$(use_with readline) \
+		$(use_with kerberos krb5) \
+		$(use_with kerberos gssapi) \
+		"$(use_enable nls nls "$(wanted_languages)")" \
+		$(use_with pam) \
+		$(use_enable !pg_legacytimestamp integer-datetimes ) \
+		$(use_with ssl openssl) \
+		$(use_enable threads thread-safety) \
+		$(use_with zlib) \
+		$(use_with ldap) \
+		|| die "configure failed"
+}
+src_compile() {
+
+	emake || die "emake failed"
+
+	cd "${S}/contrib"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	insinto /usr/include/postgresql-${SLOT}/postmaster
+	doins "${S}"/src/include/postmaster/*.h
+	dodir /usr/share/postgresql-${SLOT}/man/man1
+	tar -zxf "${S}/doc/man.tar.gz" -C "${D}"/usr/share/postgresql-${SLOT}/man man1/{ecpg,pg_config}.1
+
+	rm -r "${D}/usr/share/doc/postgresql-${SLOT}/html"
+	rm "${D}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,ipcclean,pg_controldata,pg_ctl,pg_resetxlog,pg_restore,postgres,postmaster}.1
+	dodoc README HISTORY doc/{README.*,TODO,bug.template}
+
+	cd "${S}/contrib"
+	emake DESTDIR="${D}" install || die "emake install failed"
+	cd "${S}"
+
+	dodir /etc/eselect/postgresql/slots/${SLOT}
+
+	IDIR="/usr/include/postgresql-${SLOT}"
+	cat > "${D}/etc/eselect/postgresql/slots/${SLOT}/base" <<-__EOF__
+postgres_ebuilds="\${postgres_ebuilds} ${PF}"
+postgres_prefix=/usr/$(get_libdir)/postgresql-${SLOT}
+postgres_datadir=/usr/share/postgresql-${SLOT}
+postgres_bindir=/usr/$(get_libdir)/postgresql-${SLOT}/bin
+postgres_symlinks=(
+	${IDIR} /usr/include/postgresql
+	${IDIR}/libpq-fe.h /usr/include/libpq-fe.h
+	${IDIR}/pg_config_manual.h /usr/include/pg_config_manual.h
+	${IDIR}/libpq /usr/include/libpq
+	${IDIR}/postgres_ext.h /usr/include/postgres_ext.h
+)
+__EOF__
+
+	cat >"${T}/50postgresql-94-${SLOT}" <<-__EOF__
+		LDPATH=/usr/$(get_libdir)/postgresql-${SLOT}/$(get_libdir)
+		MANPATH=/usr/share/postgresql-${SLOT}/man
+	__EOF__
+	doenvd "${T}/50postgresql-94-${SLOT}"
+
+	keepdir /etc/postgresql-${SLOT}
+}
+
+pkg_postinst() {
+	eselect postgresql update
+	[[ "$(eselect postgresql show)" = "(none)" ]] && eselect postgresql set ${SLOT}
+	elog "If you need a global psqlrc-file, you can place it in '${ROOT}/etc/postgresql-${SLOT}/'."
+}
+
+pkg_postrm() {
+	eselect postgresql update
+}