gen_usr_ldscript -a lzma

Package-Manager: portage-2.2.0_alpha142/cvs/Linux x86_64
Manifest-Sign-Key: 0x4868F14D

1 files changed, 71 insertions, 0 deletions

diff --git a/app-arch/xz-utils/xz-utils-5.0.4-r1.ebuild b/app-arch/xz-utils/xz-utils-5.0.4-r1.ebuild
new file mode 100644
index 000000000000..659f22bce438
--- /dev/null
+++ b/app-arch/xz-utils/xz-utils-5.0.4-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.4-r1.ebuild,v 1.1 2012/11/24 20:33:49 ssuominen Exp $
+
+# Remember: we cannot leverage autotools in this ebuild in order
+#           to avoid circular deps with autotools
+
+EAPI="4"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="http://git.tukaani.org/xz.git"
+	inherit git-2 autotools
+	SRC_URI=""
+	EXTRA_DEPEND="sys-devel/gettext dev-vcs/cvs >=sys-devel/libtool-2" #272880 286068
+else
+	inherit libtool
+	MY_P="${PN/-utils}-${PV/_}"
+	SRC_URI="http://tukaani.org/xz/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~ppc-aix ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	S=${WORKDIR}/${MY_P}
+	EXTRA_DEPEND=
+fi
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="utils for managing LZMA compressed files"
+HOMEPAGE="http://tukaani.org/xz/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="nls static-libs +threads"
+
+RDEPEND="!<app-arch/lzma-4.63
+	!app-arch/lzma-utils
+	!<app-arch/p7zip-4.57"
+DEPEND="${RDEPEND}
+	${EXTRA_DEPEND}"
+
+if [[ ${PV} == "9999" ]] ; then
+src_prepare() {
+	eautopoint
+	eautoreconf
+}
+else
+src_prepare() {
+	elibtoolize  # to allow building shared libs on Solaris/x64
+}
+fi
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable threads) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	gen_usr_ldscript -a lzma
+	prune_libtool_files --all
+	rm "${ED}"/usr/share/doc/xz/COPYING* || die
+	mv "${ED}"/usr/share/doc/{xz,${PF}} || die
+}
+
+pkg_preinst() {
+	preserve_old_lib /usr/$(get_libdir)/liblzma$(get_libname 0)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /usr/$(get_libdir)/liblzma$(get_libname 0)
+}