Just another bsdtar bump.

Package-Manager: portage-2.1.2.2

3 files changed, 91 insertions, 1 deletions

diff --git a/app-arch/bsdtar/ChangeLog b/app-arch/bsdtar/ChangeLog
index c745ed6f8bbe..aa10e9f6ac0e 100644
--- a/app-arch/bsdtar/ChangeLog
+++ b/app-arch/bsdtar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/bsdtar
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/bsdtar/ChangeLog,v 1.59 2007/03/11 21:56:06 drizzt Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/bsdtar/ChangeLog,v 1.60 2007/03/13 15:52:37 drizzt Exp $
+
+*bsdtar-2.0.25 (13 Mar 2007)
+
+  13 Mar 2007; Timothy Redaelli <drizzt@gentoo.org> +bsdtar-2.0.25.ebuild:
+  Just another bsdtar bump.
 
 *bsdtar-2.0.24 (11 Mar 2007)
 
diff --git a/app-arch/bsdtar/bsdtar-2.0.25.ebuild b/app-arch/bsdtar/bsdtar-2.0.25.ebuild
new file mode 100644
index 000000000000..32015460979e
--- /dev/null
+++ b/app-arch/bsdtar/bsdtar-2.0.25.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/bsdtar/bsdtar-2.0.25.ebuild,v 1.1 2007/03/13 15:52:37 drizzt Exp $
+
+inherit eutils autotools toolchain-funcs flag-o-matic
+
+MY_P="libarchive-${PV/_beta/b}"
+
+DESCRIPTION="BSD tar command"
+HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive/"
+SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="build static acl xattr"
+
+RDEPEND="!dev-libs/libarchive
+	kernel_linux? (
+		acl? ( sys-apps/acl )
+		xattr? ( sys-apps/attr )
+	)
+	!static? ( !build? (
+		app-arch/bzip2
+		sys-libs/zlib ) )"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-fs/e2fsprogs
+		virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/libarchive-1.3.1-static.patch
+	epatch "${FILESDIR}"/libarchive-2.0b6-acl.patch
+
+	eautoreconf
+	epunt_cxx
+}
+
+src_compile() {
+	local myconf
+
+	if use static || use build ; then
+		myconf="${myconf} --enable-static-bsdtar"
+	else
+		myconf="${myconf} --disable-static-bsdtar"
+	fi
+
+	# Upstream doesn't seem to care to fix the problems
+	# and I don't want to continue running after them.
+	append-flags -fno-strict-aliasing
+
+	econf \
+		--bindir=/bin \
+		$(use_enable acl) \
+		$(use_enable xattr) \
+		${myconf} || die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "emake install failed"
+
+	# Create tar symlink for FreeBSD
+	if [[ ${CHOST} == *-freebsd* ]]; then
+		dosym bsdtar /bin/tar
+		dosym bsdtar.1 /usr/share/man/man1/tar.1
+	fi
+
+	if use build; then
+		rm -rf "${D}"/usr
+		rm -rf "${D}"/lib/*.so*
+		return 0
+	fi
+
+	dodir /$(get_libdir)
+	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
+	gen_usr_ldscript libarchive.so
+}
diff --git a/app-arch/bsdtar/files/digest-bsdtar-2.0.25 b/app-arch/bsdtar/files/digest-bsdtar-2.0.25
new file mode 100644
index 000000000000..410536c56f1e
--- /dev/null
+++ b/app-arch/bsdtar/files/digest-bsdtar-2.0.25
@@ -0,0 +1,3 @@
+MD5 508c3daa2bea77b92914f0a03a8a9cf9 libarchive-2.0.25.tar.gz 574428
+RMD160 d699cb9612bba7a71616ce95d39986d34d93dd0b libarchive-2.0.25.tar.gz 574428
+SHA256 76068ac0f426e1bf565086f57e13ef2c705c2a06dd4a6044053a26dc95d51e44 libarchive-2.0.25.tar.gz 574428