x11-plugins/bubblemon/bubblemon-1.46-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit toolchain-funcs

DESCRIPTION="A fun monitoring applet for your desktop, complete with swimming duck"
HOMEPAGE="http://www.ne.jp/asahi/linux/timecop"
SRC_URI="http://www.ne.jp/asahi/linux/timecop/software/${PN}-dockapp-${PV}.tar.gz"
S="${WORKDIR}"/${PN}-dockapp-${PV}

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ppc ~sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"

RDEPEND="x11-libs/gtk+:2"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/${P}-gtk.patch
	"${FILESDIR}"/${P}-asneeded.patch
	"${FILESDIR}"/${P}-no_display.patch
)

src_compile() {
	tc-export CC PKG_CONFIG
	emake GENTOO_CFLAGS="${CFLAGS}"
}

src_install() {
	dobin bubblemon
	dodoc ChangeLog README doc/Xdefaults.sample

	insinto /usr/share/${PN}
	doins misc/*.{xcf,wav}
	exeinto /usr/share/${PN}
	doexe misc/wakwak.sh
}