blob: eabe98c085211b04278362462f8309e584f86729 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs
DESCRIPTION="Collection of tools for managing UNIX services"
HOMEPAGE="https://cr.yp.to/daemontools.html"
SRC_URI="
https://cr.yp.to/daemontools/${P}.tar.gz
https://smarden.org/pape/djb/manpages/${P}-man-20020131.tar.gz"
S="${WORKDIR}/admin/${P}/src"
LICENSE="public-domain GPL-2" # GPL-2 for init script
SLOT="0"
KEYWORDS="~alpha ~amd64 arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 sparc ~x86"
IUSE="selinux static"
RDEPEND="selinux? ( sec-policy/selinux-daemontools )"
PATCHES=(
"${FILESDIR}"/${PV}-errno.patch
"${FILESDIR}"/${PV}-C99-decls.patch
"${FILESDIR}"/${PV}-makefile.patch
"${FILESDIR}"/${PV}-implicit-func-decl-clang16.patch
"${FILESDIR}"/${PV}-const-typecasts-C99.patch
)
src_configure() {
tc-export AR CC
use static && append-ldflags -static
touch home || die
}
src_install() {
keepdir /service
dobin $(<../package/commands)
dodoc CHANGES ../package/README TODO
doman "${WORKDIR}"/${PN}-man/*.8
newinitd "${FILESDIR}"/svscan.init-0.76-r7 svscan
}
pkg_postinst() {
einfo
einfo "You can run daemontools using the svscan init.d script,"
einfo "or you could run it through inittab."
einfo "To use inittab, emerge supervise-scripts and run:"
einfo "svscan-add-to-inittab"
einfo "Then you can hup init with the command telinit q"
einfo
}
|
GitWeb
