blob: 7e2045ca3b27ed2674981aee4a212817053ab196 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
inherit autotools python-single-r1
MY_PN="OpenIPMI"
MY_P="${MY_PN}-${PV/_/-}"
DESCRIPTION="Library interface to IPMI"
HOMEPAGE="https://sourceforge.net/projects/openipmi/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="LGPL-2.1 GPL-2"
SLOT="0"
KEYWORDS="amd64 arm64 ~hppa ~ia64 ppc ~ppc64 x86"
IUSE="crypt snmp perl python static-libs tcl"
RESTRICT="test"
RDEPEND="
dev-libs/glib:2
sys-libs/gdbm:=
sys-libs/ncurses:0=
sys-libs/readline:0=
crypt? ( dev-libs/openssl:0= )
snmp? ( net-analyzer/net-snmp )
perl? ( dev-lang/perl:= )
python? ( ${PYTHON_DEPS} )
tcl? ( dev-lang/tcl:0= )"
DEPEND="${RDEPEND}
>=dev-lang/swig-1.3.21"
BDEPEND="virtual/pkgconfig"
# Gui is broken!
# python? ( tcl? ( tk? ( dev-lang/tk dev-tcltk/tix ) ) )"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
PATCHES=(
"${FILESDIR}/${PN}-2.0.26-tinfo.patch" #501510
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
# Bug #298250: parallel install fix.
sed -r -i \
-e '/^install-data-local:/s,$, install-exec-am,g' \
cmdlang/Makefile.{am,in} || die
# We touch the .in and .am above because if we use the below, the Perl stuff
# is very fragile, and often fails to link.
eautoreconf
}
src_configure() {
local myconf=(
# these binaries are for root!
--bindir="${EPREFIX}"/usr/sbin
--with-glib
--with-glibver=2.0
--with-swig
--without-tkinter
$(use_with snmp ucdsnmp yes)
$(use_with crypt openssl yes)
$(use_with perl perl yes)
$(use_with tcl tcl yes)
$(use_with python python yes)
)
# GUI is broken
#use tk && use python && use !tcl && \
# ewarn "Not building Tk GUI because it needs both Python AND Tcl"
#if use python && use tcl; then
# myconf+=( $(use_with tk tkinter) )
#else
# myconf+=( --without-tkinter )
#fi
econf "${myconf[@]}"
}
src_install() {
emake DESTDIR="${D}" install
dodoc README* FAQ ChangeLog TODO doc/IPMI.pdf lanserv/README.vm
newdoc cmdlang/README README.cmdlang
use python && python_optimize
find "${ED}" -name "*.la" -delete || die
if ! use static-libs ; then
find "${ED}" -name "*.a" -delete || die
fi
}
|
GitWeb