blob: 6566aedd07d5a814704fd7a5d505bcf9761bf944 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PV=${PV/_p/ga}
MY_P=${PN}-${MY_PV}
SUB_PV=${PV:0:3}
S="${WORKDIR}"/${PN}-${SUB_PV}
# Only the x3270 package installs fonts
FONT_PN="x3270"
FONT_S="${S}"/${FONT_PN}
inherit autotools font
DESCRIPTION="Complete 3270 (S390) access package"
HOMEPAGE="http://x3270.bgp.nu/"
SRC_URI="https://downloads.sourceforge.net/x3270/${MY_P}-src.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~s390 ~sparc ~x86"
IUSE="cjk doc gui ncurses ssl tcl"
RDEPEND="
gui? (
x11-libs/libX11
x11-libs/libXaw
x11-libs/libXmu
x11-libs/libXt
)
ssl? ( dev-libs/openssl:= )
ncurses? (
sys-libs/ncurses:=
sys-libs/readline:=
)
tcl? ( dev-lang/tcl:= )
"
DEPEND="
${RDEPEND}
gui? ( x11-base/xorg-proto )
"
BDEPEND="
gui? (
x11-apps/bdftopcf
>=x11-apps/mkfontscale-1.2.0
x11-misc/xbitmaps
)
"
PATCHES=(
"${FILESDIR}"/${PN}-4.1-musl-wint-t-fix.patch
"${FILESDIR}"/${PN}-4.2_p5-ncurses-pkg-config.patch
)
src_prepare() {
default
# Some subdirs (like c3270/x3270/s3270) install the same set of data files
# (they have the same contents). Wrap that in a retry to avoid errors.
cat <<-EOF > _install || die
#!/bin/sh
for n in 1 2 3 4 5; do
install "\$@" && exit
echo "retrying ..."
done
exit 1
EOF
chmod a+rx _install || die
# Can't use the ${INSTALL} var as top level configure also uses it.
# https://sourceforge.net/p/x3270/bugs/15/
export ac_cv_path_install="${S}"/_install
AT_NOEAUTOHEADER=yes eautoreconf
}
src_configure() {
econf \
--cache-file="${S}"/config.cache \
--enable-s3270 \
--enable-pr3287 \
$(use_enable ncurses c3270) \
$(use_enable tcl tcl3270) \
$(use_enable gui x3270) \
$(use_with gui x) \
$(use_with gui fontdir "${FONTDIR}")
}
src_install() {
use gui && dodir "${FONTDIR}"
emake DESTDIR="${D}" install{,.man}
use gui && font_src_install
}
pkg_postinst() {
use gui && font_pkg_postinst
}
pkg_postrm() {
use gui && font_pkg_postrm
}
|
GitWeb