blob: 36822f336c6c2bc6e9d7afaeb25a29402f8eee06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
MY_P="${PN}-2.8"
DESCRIPTION="A cross-platform open source C and C++ SDK for SOAP/XML Web services"
HOMEPAGE="http://gsoap2.sourceforge.net"
SRC_URI="mirror://sourceforge/gsoap2/gsoap_${PV}.zip"
S="${WORKDIR}/${MY_P}"
LICENSE="|| ( gSOAP-1.3b GPL-2+-with-openssl-exception ) GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc debug examples ipv6 gnutls +ssl"
RDEPEND="
sys-libs/zlib
gnutls? ( net-libs/gnutls )
ssl? (
dev-libs/openssl:=
)
"
DEPEND="
${RDEPEND}
"
BDEPEND="
app-arch/unzip
sys-devel/bison
sys-devel/flex
"
PATCHES=(
# Enable shared libs (bug #583398)
"${FILESDIR}/${PN}-2.8.130-shared_libs.patch"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
unset YACC LEX
local myeconfargs=(
# Don't include xlocale.h as it got removed in >=glibc-2.26
--disable-xlocale
$(use_enable debug)
$(use_enable gnutls)
$(usev ipv6 --enable-ipv6)
$(usev !ssl --disable-ssl)
)
econf "${myeconfargs[@]}"
}
src_install() {
emake DESTDIR="${D}" install
# Yes, we also install the license-file since
# it contains info about how to apply the licenses.
dodoc *.txt
docinto html
dodoc changelog.md
find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
if use examples; then
insinto /usr/share/${PN}/examples
doins -r gsoap/samples/*
fi
if use doc; then
docinto html
dodoc -r gsoap/doc/*
fi
}
|
GitWeb