net-dialup/rp-l2tp/rp-l2tp-0.4-r5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools toolchain-funcs

DESCRIPTION="User-space implementation of L2TP for Linux and other UNIX systems"
HOMEPAGE="https://sourceforge.net/projects/rp-l2tp/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2+ GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

PATCHES=(
	"${FILESDIR}/${P}-gentoo.patch"
	"${FILESDIR}/${P}-flags.patch"
	"${FILESDIR}/${P}-build.patch"
	"${FILESDIR}/${P}-parallel-build.patch"
	"${FILESDIR}/${P}-clang16-build-fix.patch"
)

src_prepare() {
	default

	eautoreconf #871210

	tc-export AR CC
}

src_install() {
	emake RPM_INSTALL_ROOT="${D}" install
	einstalldocs

	newdoc l2tp.conf rp-l2tpd.conf

	docinto libevent
	dodoc -r libevent/Doc/.
	docompress -x /usr/share/doc/${PF}/libevent

	newinitd "${FILESDIR}"/rp-l2tpd-init rp-l2tpd
}