blob: 17afb338d80fd97c1f550dc67d891266f128de27 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools multilib-minimal
MY_PV="$(ver_rs 1 _)"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Free MPEG-4 audio codecs by AudioCoding.com"
HOMEPAGE="https://www.audiocoding.com"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="LGPL-2.1 MPEG-4"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
S="${WORKDIR}/${MY_P}"
src_prepare() {
default
sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466984
eautoreconf
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf --disable-static
# do not build the frontend for non-native abis
if ! multilib_is_native_abi; then
sed -i -e 's/frontend//' Makefile || die
fi
}
multilib_src_install_all() {
einstalldocs
# no static archives
find "${ED}" -type f -name '*.la' -delete || die
}
|
GitWeb
