blob: 9a30d0e999cf978711ace55b5b729da55084dcc6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit font
DESCRIPTION="Microsoft's TrueType core fonts"
HOMEPAGE="https://corefonts.sourceforge.net/"
SRC_URI="mirror://gentoo/EUupdate.EXE
mirror://sourceforge/corefonts/andale32.exe
mirror://sourceforge/corefonts/arialb32.exe
mirror://sourceforge/corefonts/comic32.exe
mirror://sourceforge/corefonts/courie32.exe
mirror://sourceforge/corefonts/georgi32.exe
mirror://sourceforge/corefonts/impact32.exe
mirror://sourceforge/corefonts/webdin32.exe
mirror://sourceforge/corefonts/wd97vwr32.exe"
S="${WORKDIR}"
LICENSE="MSttfEULA"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="X tahoma"
BDEPEND="app-arch/cabextract"
FONT_SUFFIX="ttf"
src_unpack() {
for exe in ${A} ; do
echo ">>> Unpacking ${exe} to ${WORKDIR}"
cabextract --lowercase "${DISTDIR}"/${exe} > /dev/null \
|| die "failed to unpack ${exe}"
done
if use tahoma; then
cabextract -F 'tahoma.ttf' "${WORKDIR}/viewer1.cab" > /dev/null \
|| die "failed to unpack tahoma.ttf"
fi
}
src_install() {
font_src_install
# The license explicitly states that the license must be distributed with the
# fonts. The only way to do that for the binpkg is to include it.
dodoc license.txt
}
|
GitWeb
