games-simulation/crrcsim/crrcsim-0.9.13-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools desktop

DESCRIPTION="Model-airplane flight simulation program"
HOMEPAGE="https://sourceforge.net/projects/crrcsim/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="portaudio"

RDEPEND="
	dev-libs/gmp:=
	media-libs/libsdl[X,sound,joystick,opengl,video]
	media-libs/plib
	virtual/glu
	virtual/jpeg
	virtual/opengl
	portaudio? ( media-libs/portaudio )"
DEPEND="
	${RDEPEND}
	sci-mathematics/cgal"

PATCHES=(
	"${FILESDIR}"/${P}-gcc6.patch
	"${FILESDIR}"/${P}-overlink.patch
	"${FILESDIR}"/${P}-clang.patch
)

DOCS=( AUTHORS HISTORY )

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	econf ac_cv_header_portaudio_h=$(usex portaudio)
}

src_install() {
	default

	doicon packages/icons/${PN}.png
	make_desktop_entry ${PN} CRRCSim
}