blob: 0e10b45ac3d4983611ee9068dcd14e69783bc89e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
PYTHON_REQ_USE="sqlite?"
inherit distutils-r1 eutils flag-o-matic
MY_PN="SQLAlchemy"
MY_P="${MY_PN}-${PV/_beta/b}"
DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
HOMEPAGE="https://www.sqlalchemy.org/ https://pypi.org/project/SQLAlchemy/"
SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
IUSE="doc examples +sqlite test"
REQUIRED_USE="test? ( sqlite )"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
S="${WORKDIR}/${MY_P}"
distutils_enable_tests pytest
python_prepare_all() {
local PATCHES=(
"${FILESDIR}"/sqlalchemy-pytest-deprecation.patch
)
# Disable tests hardcoding function call counts specific to Python versions.
rm -r test/aaa_profiling || die
distutils-r1_python_prepare_all
}
python_compile() {
if ! python_is_python3; then
local CFLAGS=${CFLAGS}
append-cflags -fno-strict-aliasing
fi
distutils-r1_python_compile
}
python_install_all() {
use doc && HTML_DOCS=( doc/. )
use examples && dodoc -r examples
distutils-r1_python_install_all
}
pkg_postinst() {
optfeature "MySQL support" dev-python/mysql-python dev-python/mysql-connector-python
optfeature "mssql support" dev-python/pymssql
optfeature "postgresql support" dev-python/psycopg:2
}
|
GitWeb
