blob: 5eb673b23e4ea8e5eb0335eccaee90f46d17aa53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6..9} )
inherit distutils-r1 flag-o-matic
MY_PN="${PN}2"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="PostgreSQL database adapter for Python"
HOMEPAGE="https://www.psycopg.org https://pypi.org/project/psycopg2/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
S=${WORKDIR}/${MY_P}
LICENSE="LGPL-3+"
SLOT="2"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ~ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
IUSE="debug test"
RESTRICT="!test? ( test )"
# automagic dep on mxdatetime (from egenix-mx-base)
# the package was removed, so let's just make sure it's gone
RDEPEND=">=dev-db/postgresql-8.1:*"
DEPEND="${RDEPEND}
test? ( >=dev-db/postgresql-8.1[server] )
!!dev-python/egenix-mx-base"
python_compile() {
local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS}
! python_is_python3 && append-flags -fno-strict-aliasing
distutils-r1_python_compile
}
python_prepare_all() {
if use debug; then
sed -i 's/^\(define=\)/\1PSYCOPG_DEBUG,/' setup.cfg || die
fi
distutils-r1_python_prepare_all
}
src_test() {
initdb -D "${T}"/pgsql || die
# TODO: random port
pg_ctl -w -D "${T}"/pgsql start \
-o "-h '' -k '${T}'" || die
createdb -h "${T}" psycopg2_test || die
local -x PSYCOPG2_TESTDB_HOST="${T}"
distutils-r1_src_test
pg_ctl -w -D "${T}"/pgsql stop || die
}
python_test() {
"${EPYTHON}" -c "
import tests
tests.unittest.main(defaultTest='tests.test_suite')
" --verbose || die "Tests fail with ${EPYTHON}"
}
|
GitWeb
