blob: 8aca0d1edee6f8c6851d1b841a3b77011ac92f15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
inherit python-r1 qmake-utils
DESCRIPTION="Python bindings for QtWebEngine"
HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro https://pypi.org/project/PyQtWebEngine/"
MY_P=${PN}-${PV/_pre/.dev}
if [[ ${PV} == *_pre* ]]; then
SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
else
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
fi
S=${WORKDIR}/${MY_P}
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 ~arm ~arm64 x86"
IUSE="debug"
REQUIRED_USE="
${PYTHON_REQUIRED_USE}
"
RDEPEND="
${PYTHON_DEPS}
>=dev-python/PyQt5-5.15[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
>=dev-python/PyQt5-sip-4.19.22:=[${PYTHON_USEDEP}]
dev-qt/qtcore:5
dev-qt/qtwebengine:5[widgets]
"
DEPEND="${RDEPEND}
>=dev-python/sip-4.19.22[${PYTHON_USEDEP}]
"
src_configure() {
configuration() {
local myconf=(
"${EPYTHON}"
"${S}"/configure.py
--qmake="$(qt5_get_bindir)"/qmake
$(usex debug '--debug --trace' '')
--verbose
)
echo "${myconf[@]}"
"${myconf[@]}" || die
# Fix parallel install failure
sed -i -e '/INSTALLS += distinfo/i distinfo.depends = install_subtargets install_pep484_stubs install_api' \
${PN}.pro || die
# Run eqmake to respect toolchain and build flags
eqmake5 -recursive ${PN}.pro
}
python_foreach_impl run_in_build_dir configuration
}
src_compile() {
python_foreach_impl run_in_build_dir default
}
src_install() {
installation() {
emake INSTALL_ROOT="${D}" install
python_optimize
}
python_foreach_impl run_in_build_dir installation
einstalldocs
}
|
GitWeb
