blob: acc5def6a81d9fd251242461873a15c7eae970ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
inherit common-lisp-3
MY_P="v${PV}"
DESCRIPTION="A library which provides Common Lisp implementations with knowledge about Unicode characters."
HOMEPAGE="http://weitz.de/cl-unicode/"
SRC_URI="https://github.com/edicl/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE=""
DEPEND="dev-lisp/flexi-streams"
RDEPEND="dev-lisp/cl-ppcre"
COMMONLISPS="sbcl clisp clozurecl cmucl ecls openmcl"
find-lisp-impl() {
for lisp in ${COMMONLISPS} ; do
[[ "$(best_version dev-lisp/${lisp})" ]] && echo "${lisp}" && return
done
die "No CommonLisp implementation found"
}
src_compile() {
# cl-unicode builds parts of its source code automatically the first time it
# is compiled, so we compile it here.
local lispimpl=$(find-lisp-impl)
local initclunicode="(progn (push \"${S}/\" asdf:*central-registry*) (require :${PN}))"
common-lisp-export-impl-args "${lispimpl}"
${lispimpl} ${CL_EVAL} "${initclunicode}"
}
src_install() {
common-lisp-install-sources *.lisp test/
common-lisp-install-sources -t all build/
common-lisp-install-asdf
dodoc CHANGELOG
dohtml doc/index.html
}
|
GitWeb
