blob: 360145b9b2d3df2b0d2b281b47512a3759ce9ef3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module
GIT_COMMIT=667bdef45c4e01380867f4be5bb0c7e0ece35dd6
DESCRIPTION="Prometheus exporter for memcached"
HOMEPAGE="https://github.com/prometheus/memcached_exporter"
SRC_URI="https://github.com/prometheus/memcached_exporter/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://dev.gentoo.org/~williamh/dist/${P}-deps.tar.xz"
LICENSE="Apache-2.0 BSD BSD-2 MIT"
SLOT="0"
KEYWORDS="~amd64"
BDEPEND="dev-util/promu"
DEPEND="acct-group/memcached_exporter
acct-user/memcached_exporter"
RDEPEND="${DEPEND}"
# tests require the memcached_exporter daemon to be running locally
RESTRICT+=" test "
src_prepare() {
default
sed -i \
-e "s/{{.Branch}}/HEAD/" \
-e "s/{{.Revision}}/${GIT_COMMIT}/" \
.promu.yml || die "sed failed"
}
src_compile() {
promu build -v --prefix bin || die
}
src_install() {
dobin bin/*
dodoc *.md
keepdir /var/log/${PN}
fowners ${PN}:${PN} /var/log/${PN}
newinitd "${FILESDIR}"/${PN}.initd ${PN}
newconfd "${FILESDIR}"/${PN}.confd ${PN}
}
|
GitWeb
