1 files changed, 50 insertions, 0 deletions
diff --git a/x11-libs/xpyb/xpyb-1.3.1-r4.ebuild b/x11-libs/xpyb/xpyb-1.3.1-r4.ebuild
new file mode 100644
index 000000000000..1e7d210bc6ae
--- /dev/null
+++ b/x11-libs/xpyb/xpyb-1.3.1-r4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+AUTOTOOLS_AUTORECONF=1
+
+inherit flag-o-matic xorg-2 python-r1
+
+#EGIT_REPO_URI="https://anongit.freedesktop.org/git/xcb/xpyb.git"
+SRC_URI="https://xcb.freedesktop.org/dist/${P}.tar.bz2"
+DESCRIPTION="XCB-based Python bindings for the X Window System"
+HOMEPAGE="https://xcb.freedesktop.org/"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="selinux"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND=">=x11-libs/libxcb-1.7
+	>=x11-proto/xcb-proto-1.7.1[${PYTHON_USEDEP}]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-python.patch
+	"${FILESDIR}"/${PN}-1.3.1-xcbproto-1.9.patch
+	"${FILESDIR}"/${PN}-1.3.1-xcbproto-1.13.patch
+)
+DOCS=( NEWS README )
+
+pkg_setup() {
+	xorg-2_pkg_setup
+	XORG_CONFIGURE_OPTIONS=(
+		$(use_enable selinux)
+	)
+}
+
+src_configure() {
+	append-cflags -fno-strict-aliasing
+	python_foreach_impl xorg-2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl xorg-2_src_compile
+}
+
+src_install() {
+	python_foreach_impl xorg-2_src_install
+}