1 files changed, 47 insertions, 0 deletions
diff --git a/sys-libs/libcap/libcap-2.20.ebuild b/sys-libs/libcap/libcap-2.20.ebuild
new file mode 100644
index 000000000000..ee69ae865c9b
--- /dev/null
+++ b/sys-libs/libcap/libcap-2.20.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="2"
+
+inherit eutils multilib toolchain-funcs pam
+
+DESCRIPTION="POSIX 1003.1e capabilities"
+HOMEPAGE="http://www.friedhoff.org/posixfilecaps.html"
+SRC_URI="mirror://kernel/linux/libs/security/linux-privs/libcap${PV:0:1}/${P}.tar.bz2"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="pam"
+
+RDEPEND="sys-apps/attr
+	pam? ( virtual/pam )"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.20-build-system-fixes.patch
+	epatch "${FILESDIR}"/${PN}-2.20-ignore-RAISE_SETFCAP-install-failures.patch
+	sed -i \
+		-e "/^PAM_CAP/s:=.*:=$(use pam && echo yes || echo no):" \
+		-e '/^DYNAMIC/s:=.*:=yes:' \
+		-e "/^lib=/s:=.*:=/usr/$(get_libdir):" \
+		Make.Rules
+}
+
+src_compile() {
+	tc-export BUILD_CC CC AR RANLIB
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	gen_usr_ldscript -a cap
+
+	dopammod pam_cap/pam_cap.so
+	dopamsecurity '' pam_cap/capability.conf
+
+	dodoc CHANGELOG README doc/capability.notes
+}