1 files changed, 56 insertions, 0 deletions
diff --git a/kde-frameworks/kwallet/kwallet-5.36.0.ebuild b/kde-frameworks/kwallet/kwallet-5.36.0.ebuild
new file mode 100644
index 000000000000..8037d189d022
--- /dev/null
+++ b/kde-frameworks/kwallet/kwallet-5.36.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit kde5
+
+DESCRIPTION="Framework providing desktop-wide storage for passwords"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gpg +man"
+
+RDEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+	dev-libs/libgcrypt:0=
+	gpg? ( >=app-crypt/gpgme-1.7.1[cxx,qt5] )
+"
+DEPEND="${RDEPEND}
+	man? ( $(add_frameworks_dep kdoctools) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package gpg Gpgmepp)
+		$(cmake-utils_use_find_package man KF5DocTools)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	if ! has_version "kde-plasma/kwallet-pam" || ! has_version "kde-apps/kwalletmanager:5" ; then
+		elog
+		elog "Install kde-plasma/kwallet-pam for auto-unlocking after account login."
+		elog "Install kde-apps/kwalletmanager:5 to manage your kwallet."
+		elog
+	fi
+	if has_version "kde-apps/kwalletd"; then
+		elog "Starting with 5.34.0-r1, ${PN} is able to serve applications"
+		elog "that still require old kwalletd4. After migration has finished,"
+		elog "kde-apps/kwalletd can be removed."
+	fi
+	elog "For more information, read https://wiki.gentoo.org/wiki/KDE#KWallet"
+}