1 files changed, 58 insertions, 0 deletions
diff --git a/app-editors/kile/kile-2.1.3-r1.ebuild b/app-editors/kile/kile-2.1.3-r1.ebuild
new file mode 100644
index 000000000000..e6f2e9ee83bb
--- /dev/null
+++ b/app-editors/kile/kile-2.1.3-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+KDE_DOC_DIRS="doc"
+KDE_HANDBOOK="optional"
+MY_P=${P/_beta/b}
+inherit kde4-base
+
+DESCRIPTION="A Latex Editor and TeX shell for KDE"
+HOMEPAGE="http://kile.sourceforge.net/"
+[[ ${PV} != *9999* ]] && SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="FDL-1.2 GPL-2"
+KEYWORDS="amd64 ~ppc x86"
+SLOT="4"
+IUSE="debug +pdf +png"
+
+DEPEND="
+	x11-misc/shared-mime-info
+"
+RDEPEND="${DEPEND}
+	$(add_kdeapps_dep kdebase-data)
+	$(add_kdeapps_dep konsole)
+	|| (
+		$(add_kdeapps_dep okular 'pdf?,postscript')
+		app-text/acroread
+	)
+	virtual/latex-base
+	virtual/tex-base
+	pdf? (
+		|| (
+			app-text/dvipdfmx
+			>=app-text/texlive-core-2014
+		)
+		app-text/ghostscript-gpl
+	)
+	png? (
+		app-text/dvipng
+		media-gfx/imagemagick[png]
+	)
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( kile-remote-control.txt )
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# I know upstream wants to help us but it doesn't work..
+	sed -e '/INSTALL( FILES AUTHORS/s/^/#DISABLED /' \
+		-i CMakeLists.txt || die
+
+	[[ ${PV} != *9999* ]] && { use handbook || rm -fr doc ; }
+}