1 files changed, 52 insertions, 0 deletions
diff --git a/app-admin/monit/monit-5.17.1.ebuild b/app-admin/monit/monit-5.17.1.ebuild
new file mode 100644
index 000000000000..df1ef806e07d
--- /dev/null
+++ b/app-admin/monit/monit-5.17.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit pam systemd
+
+DESCRIPTION="a utility for monitoring and managing daemons or similar programs running on a Unix system"
+HOMEPAGE="http://mmonit.com/monit/"
+SRC_URI="http://mmonit.com/monit/dist/${P}.tar.gz"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="libressl pam ssl"
+
+RDEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl )
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	sys-devel/bison
+	pam? ( virtual/pam )"
+
+src_prepare() {
+	default
+
+	sed -i -e '/^INSTALL_PROG/s/-s//' Makefile.in || die "sed failed in Makefile.in"
+}
+
+src_configure() {
+	econf $(use_with ssl) $(use_with pam)
+}
+
+src_install() {
+	default
+
+	dodoc README
+
+	insinto /etc; insopts -m600; doins monitrc
+	newinitd "${FILESDIR}"/monit.initd-5.0-r1 monit
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	use pam && newpamd "${FILESDIR}"/${PN}.pamd ${PN}
+}
+
+pkg_postinst() {
+	elog "Sample configurations are available at:"
+	elog "http://mmonit.com/monit/documentation/"
+}