xfce-extra/xfce4-notifyd: Bump to 0.9.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/xfce-extra/xfce4-notifyd/Manifest b/xfce-extra/xfce4-notifyd/Manifest
index ab53fbfd909e..1859128904af 100644
--- a/xfce-extra/xfce4-notifyd/Manifest
+++ b/xfce-extra/xfce4-notifyd/Manifest
@@ -1 +1,2 @@
 DIST xfce4-notifyd-0.9.4.tar.bz2 732160 BLAKE2B d0c47875acf638f44ae8188c7a39f1785a9e3c489f4fad209e9c591780a91b0439037a0c62351619f71d2765dacf11a786d5678c03ec846f4aa0a0bc0b823166 SHA512 d3339ec3555f27e624e643b52ce4de2a0834d38f675b286976abcb4e143cbbb32665b1f36fbff23791c152e1f0616b752a7f049045fc32829c27c0a87d82df94
+DIST xfce4-notifyd-0.9.5.tar.bz2 740324 BLAKE2B 900b9487a888e7d1b7112d1f088605d4773d9baa7d17a369ef0cc4e6e00ecfb9ac72ba760044031090048e1d1aec2a8ef5c11c5246ff84b9a14ccdfbda014138 SHA512 9e8d81ccb16c3eb72ebea24ac03a0594d3f9ddd20c7edcaf9f68e288b2d5115294d5c9e2911c15e6d8032d36cdcfc423ee51b56a20268a035a3fb7ca65c41bdc
diff --git a/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.5.ebuild b/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.5.ebuild
new file mode 100644
index 000000000000..f1b06c391860
--- /dev/null
+++ b/xfce-extra/xfce4-notifyd/xfce4-notifyd-0.9.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Notification daemon for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/apps/notifyd/start
+	https://gitlab.xfce.org/apps/xfce4-notifyd/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="sound wayland X"
+
+DEPEND="
+	>=dev-db/sqlite-3.34:3
+	>=dev-libs/glib-2.68.0:2
+	>=sys-apps/dbus-1.0
+	>=x11-libs/gtk+-3.22:3[wayland?,X?]
+	>=x11-libs/libnotify-0.7
+	>=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfce4-panel-4.14.0:=
+	>=xfce-base/xfconf-4.10:=
+	sound? (
+		>=media-libs/libcanberra-0.30[gtk3]
+	)
+	wayland? (
+		>=gui-libs/gtk-layer-shell-0.7.0
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+
+		# just service files
+		--enable-systemd
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}