x11-misc/evolvotron: Depend on dev-qt/qtwidgets:5, drop old HOMEPAGE

Package-Manager: Portage-3.0.7, Repoman-3.0.1
Closes: https://bugs.gentoo.org/724630
Closes: https://bugs.gentoo.org/742692
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-misc/evolvotron/evolvotron-0.7.1-r1.ebuild b/x11-misc/evolvotron/evolvotron-0.7.1-r1.ebuild
new file mode 100644
index 000000000000..c8f3df726e12
--- /dev/null
+++ b/x11-misc/evolvotron/evolvotron-0.7.1-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit qmake-utils
+
+DESCRIPTION="Generative art image evolver"
+HOMEPAGE="
+	https://sourceforge.net/projects/evolvotron/
+"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+DEPEND="${RDEPEND}"
+
+DOCS=(
+	BUGS NEWS README TODO USAGE
+)
+HTML_DOCS=(
+	evolvotron.html
+)
+S=${WORKDIR}/${PN}
+
+src_configure() {
+	eqmake5 main.pro
+}
+
+src_compile() {
+	local etsubdir
+	for etsubdir in \
+		libfunction libevolvotron evolvotron evolvotron_render evolvotron_mutate
+		do
+		emake sub-${etsubdir}
+	done
+}
+
+src_install() {
+	local bin
+	for bin in ${PN}{,_mutate,_render}; do
+		dobin ${bin}/${bin}
+	done
+	doman man/man1/*
+	einstalldocs
+}