sys-process/xjobs: update EAPI 7 -> 8, add missing BDEPEND

The ./configure script for this package needs sys-apps/which to detect
(f)lex. Obviously it would be better if it used "command -v", but to
avoid autoreconf'ing, this fixes the problem for now.

Closes: https://bugs.gentoo.org/940543
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/sys-process/xjobs/xjobs-20200726-r1.ebuild b/sys-process/xjobs/xjobs-20200726-r1.ebuild
new file mode 100644
index 000000000000..a9e6b55605c4
--- /dev/null
+++ b/sys-process/xjobs/xjobs-20200726-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Reads commands line by line and executes them in parallel"
+HOMEPAGE="https://www.maier-komor.de/xjobs.html"
+SRC_URI="https://www.maier-komor.de/${PN}/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+# The ./configure script uses sys-apps/which to locate flex...
+BDEPEND="
+	app-alternatives/lex
+	sys-apps/which
+"
+
+# The ncurses/terminfo libraries are used to provide color and status
+# support; but, they're detected and enabled automagically by the build
+# system. Thus it would do no good to hide them behind a USE flag that
+# can't be turned off.
+DEPEND="sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/xjobs-20200726-command-v.patch"
+	"${FILESDIR}/xjobs-20200726-dont-page-tests.patch"
+)
+
+src_install() {
+	default
+	use examples && dodoc -r examples
+}