sys-kernel/gentoo-kernel-bin: bump to 5.4.136-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 2fcefcdf42da..c300d7f7a5e3 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -44,6 +44,7 @@ DIST gentoo-kernel-5.4.135-1.amd64.xpak 61365037 BLAKE2B 40eee7098546c0adddef5ac
 DIST gentoo-kernel-5.4.135-1.arm64.xpak 58020226 BLAKE2B cbce1061818daa8949ac926bad8b7e5162029ff6c21e51e90ada2f3353304c4fa68bca02cd5910ab2a089997ca6c85e601196f947ea2f0b572433b14e062e067 SHA512 971a4f99526cadf9dc5d6a13c48399c1fc3dbb57e859594b6efe6d423136405631b231563582cd282732a259574b1b8f11e8c2631c578d93c3057dcadeba3e1d
 DIST gentoo-kernel-5.4.135-1.x86.xpak 53141492 BLAKE2B 501bc60cd72cab3bfae35ef59989e4c0136d90032989a9ed6a13c2a63f2ec21e6925ea56058dd2799fd037ee89d95bcc3541d5857be5d664bba71a668f40afff SHA512 479720b66fd004a3ce5baf25f0ac3564b5f8f980c473cf31dd64deba243a9862d931b195b52c09e62f9ee6e2a3bd2b4e632d93b4632fdd52f6338f018254c461
 DIST gentoo-kernel-5.4.136-1.amd64.xpak 61421139 BLAKE2B 797b11e6719fd3800b27517204533f020b94261881daaab0c97fb3080c35bd0d91da1868984a3e14817dabb36f350474a85f44a6be0b538ece6a9db45cb4a764 SHA512 03f4a815846965ce367d43a2a9eaacf75b031929617568099388d94bb874ce6fe2bd5a0231fc89b0803f0411e11b159d74158d8de2be01568ff53d5f199e390c
+DIST gentoo-kernel-5.4.136-1.arm64.xpak 57991376 BLAKE2B 8c5a8d30fe8362a0ea91efd4249b804d29d7ea436255b11f7379f12464cbeb0d25ffdb520f7aa0873e8d3522f9984c7946fa0e07a5f47251b55d3fb5c7297d39 SHA512 13008c837b323f9897627e3d091b1cfeea3443b62356c05413b7afff0a66ea3a4ab2d7cfa90a5b488a0f9ec938296a150bc43b12bc81e6c6a0b3d86033b7d99b
 DIST gentoo-kernel-5.4.136-1.x86.xpak 53155965 BLAKE2B dda19ed3567e9d97385a7fed5683c681405599177df084c085be0b02a946c9180ce23b970e26311738128a70312543eb768af9744fa1fdda2420bafd99a517d4 SHA512 905a8ab761771534f0d54af4843940c8695ed27225f68fa17187cf336da074c68e72e891f58205a9cf224a7d100eb84bf3ec1c50fd5a1070aa636823f9ea0115
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.136-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.136-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.136-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}