sci-libs/tensorflow: backport support for grpc-1.23

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Jason Zaman <perfinion@gentoo.org>

2 files changed, 342 insertions, 0 deletions

diff --git a/sci-libs/tensorflow/Manifest b/sci-libs/tensorflow/Manifest
index 3ec2a37712af..73a0186fdd72 100644
--- a/sci-libs/tensorflow/Manifest
+++ b/sci-libs/tensorflow/Manifest
@@ -23,4 +23,5 @@ DIST rules_docker-b8ff6a85ec359db3fd5657accd3e524daf12016d.tar.gz 460121 BLAKE2B
 DIST tensorflow-1.13.1.tar.gz 31614228 BLAKE2B 3e78309744747afd5a0929eebccb414efe51320f9291424ef6e3cb848f265aaac5ff16a7064c7aac8094f06b1edb61aa9fe22a55c28c23cfc4e2a6f640f4f12d SHA512 1e5c020a82b0b502c9c6fc9439905e19e8f1fb07e32740a5e2c70f4a3565c8c87053ccdcad360e95550dad648154e399ca8e352fb97a1788acfec3b87bf323bb
 DIST tensorflow-1.14.0-python-license.rst.txt 45132 BLAKE2B 8a8ace4b64fd9eda1932272704dd4fea002d2562cd9c2c94470d3ff5de58bb171ff849d3f998ea90cd779d1084d39af1267aca8400b74b701205d2e76e6a2628 SHA512 c79c42f4ceecf33c8f8778ca17b53595b75d5d0bdf30b11058cf01dd70a6351f530ca9dd846460aba14edc1d5876f7bf6fa0f9f49f7915590b0f54d267ce3856
 DIST tensorflow-1.14.0.tar.gz 41335204 BLAKE2B d91d84c5d86c838cc659c45e28cf3c8a9ec9a02f5854a1826680806dae41cdd00ea49a6d2c04f2019b3400c6e267c6ca6f3b28e43b244569dca174ff7f2c59d6 SHA512 ac9ea5a2d1c761aaafbdc335259e29c128127b8d069ec5b206067935180490aa95e93c7e13de57f7f54ce4ba4f34a822face22b4a028f60185edb380e5cd4787
+DIST tensorflow-patches-1.14.0-r2.tar.bz2 7213 BLAKE2B 51719fc02049d564b7e5c00a76375af9a7e8dfc73753ba5f0d53163dc1fa00d23bb7ed03553a0bce68b8b90cd5bfe21d29e7a57a827db2c68ceef65f3cb0e925 SHA512 35e1a410060cdde99df148bfd06f042b91e021f7a692ae9c0100c67555de553bc248d73db762ed0239117296fb1147e2b67cdf0dd3dc94dee6fe9804c08a7360
 DIST tensorflow-python-license.rst.txt 45132 BLAKE2B 770ddd87adc745a021daac01a284131825a33f176002a28b20a2251246183bf7ab4686305620678285e4a216a37f01b3ad953fe7864fa79611cccde156d69ab6 SHA512 2d5a3783ec340f24797e89c78007ee95ab753eb5ee8198c739544f9e1159895f7abe816d6b3c66620f8d7b64641d2a7f44ff0a5b4f2f941928f4733157c7995e
diff --git a/sci-libs/tensorflow/tensorflow-1.14.0-r2.ebuild b/sci-libs/tensorflow/tensorflow-1.14.0-r2.ebuild
new file mode 100644
index 000000000000..b30050d97da7
--- /dev/null
+++ b/sci-libs/tensorflow/tensorflow-1.14.0-r2.ebuild
@@ -0,0 +1,341 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 python{3_5,3_6,3_7} )
+MY_PV=${PV/_rc/-rc}
+MY_P=${PN}-${MY_PV}
+
+inherit bazel check-reqs cuda distutils-r1 flag-o-matic toolchain-funcs
+
+DESCRIPTION="Computation framework using data flow graphs for scalable machine learning"
+HOMEPAGE="https://www.tensorflow.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cuda mpi +python"
+CPU_USE_FLAGS_X86="sse sse2 sse3 sse4_1 sse4_2 avx avx2 fma3 fma4"
+for i in $CPU_USE_FLAGS_X86; do
+	IUSE+=" cpu_flags_x86_$i"
+done
+
+# distfiles that bazel uses for the workspace, will be copied to basel-distdir
+bazel_external_uris="
+	http://www.kurims.kyoto-u.ac.jp/~ooura/fft.tgz -> oourafft-20061228.tgz
+	https://bitbucket.org/eigen/eigen/get/a0d250e79c79.tar.gz -> eigen-a0d250e79c79.tar.gz
+	https://github.com/abseil/abseil-cpp/archive/daf381e8535a1f1f1b8a75966a74e7cca63dee89.tar.gz -> abseil-cpp-daf381e8535a1f1f1b8a75966a74e7cca63dee89.tar.gz
+	https://github.com/bazelbuild/bazel-skylib/archive/0.6.0.tar.gz -> bazel-skylib-0.6.0.tar.gz
+	https://github.com/bazelbuild/rules_closure/archive/cf1e44edb908e9616030cc83d085989b8e6cd6df.tar.gz -> bazelbuild-rules_closure-cf1e44edb908e9616030cc83d085989b8e6cd6df.tar.gz
+	https://github.com/bazelbuild/rules_swift/releases/download/0.9.0/rules_swift.0.9.0.tar.gz -> bazelbuild-rules_swift.0.9.0.tar.gz
+	https://github.com/bazelbuild/rules_docker/archive/b8ff6a85ec359db3fd5657accd3e524daf12016d.tar.gz -> rules_docker-b8ff6a85ec359db3fd5657accd3e524daf12016d.tar.gz
+	https://github.com/google/farmhash/archive/816a4ae622e964763ca0862d9dbd19324a1eaf45.tar.gz -> farmhash-816a4ae622e964763ca0862d9dbd19324a1eaf45.tar.gz
+	https://github.com/google/gemmlowp/archive/12fed0cd7cfcd9e169bf1925bc3a7a58725fdcc3.zip -> gemmlowp-12fed0cd7cfcd9e169bf1925bc3a7a58725fdcc3.zip
+	https://github.com/google/highwayhash/archive/fd3d9af80465e4383162e4a7c5e2f406e82dd968.tar.gz -> highwayhash-fd3d9af80465e4383162e4a7c5e2f406e82dd968.tar.gz
+	https://github.com/nlopezgi/bazel-toolchains/archive/94d31935a2c94fe7e7c7379a0f3393e181928ff7.tar.gz -> bazel-toolchains-94d31935a2c94fe7e7c7379a0f3393e181928ff7.tar.gz
+	cuda? (
+		https://github.com/nvidia/nccl/archive/f93fe9bfd94884cec2ba711897222e0df5569a53.tar.gz -> nvidia-nccl-f93fe9bfd94884cec2ba711897222e0df5569a53.tar.gz
+		https://github.com/NVlabs/cub/archive/1.8.0.zip -> cub-1.8.0.zip
+	)
+	python? (
+		https://github.com/intel/ARM_NEON_2_x86_SSE/archive/1200fe90bb174a6224a525ee60148671a786a71f.tar.gz -> ARM_NEON_2_x86_SSE-1200fe90bb174a6224a525ee60148671a786a71f.tar.gz
+		http://mirror.tensorflow.org/docs.python.org/2.7/_sources/license.rst.txt -> tensorflow-1.14.0-python-license.rst.txt
+		https://pypi.python.org/packages/bc/cc/3cdb0a02e7e96f6c70bd971bc8a90b8463fda83e264fa9c5c1c98ceabd81/backports.weakref-1.0rc1.tar.gz
+	)"
+
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz
+		https://dev.gentoo.org/~perfinion/patches/tensorflow-patches-${PVR}.tar.bz2
+		${bazel_external_uris}"
+
+RDEPEND="
+	app-arch/snappy
+	dev-db/lmdb
+	dev-db/sqlite
+	dev-libs/icu
+	>=dev-libs/jsoncpp-1.9
+	dev-libs/libpcre
+	dev-libs/nsync
+	dev-libs/openssl:0=
+	>=dev-libs/protobuf-3.6.0:=
+	>=dev-libs/re2-0.2018.04.01
+	media-libs/giflib
+	media-libs/libjpeg-turbo
+	media-libs/libpng:0
+	>=net-libs/grpc-1.22.0
+	net-misc/curl
+	sys-libs/zlib
+	>=sys-apps/hwloc-2
+	cuda? (
+		>=dev-util/nvidia-cuda-toolkit-9.1[profiler]
+		dev-libs/cudnn
+	)
+	mpi? ( virtual/mpi )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-libs/flatbuffers-1.8.0
+		dev-python/absl-py[${PYTHON_USEDEP}]
+		>=dev-python/astor-0.7.1[${PYTHON_USEDEP}]
+		dev-python/gast[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/google-pasta[${PYTHON_USEDEP}]
+		>=dev-python/protobuf-python-3.6.0[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/termcolor[${PYTHON_USEDEP}]
+		>=dev-python/grpcio-1.22.0[${PYTHON_USEDEP}]
+		>=dev-python/wrapt-1.11.1[${PYTHON_USEDEP}]
+		>=net-libs/google-cloud-cpp-0.10.0
+		>=sci-libs/keras-applications-1.0.6[${PYTHON_USEDEP}]
+		>=sci-libs/keras-preprocessing-1.0.5[${PYTHON_USEDEP}]
+		>=sci-visualization/tensorboard-1.13.0[${PYTHON_USEDEP}]
+		virtual/python-enum34[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	dev-python/mock"
+PDEPEND="python? (
+		>=sci-libs/tensorflow-estimator-1.13.0[${PYTHON_USEDEP}]
+	)"
+BDEPEND="
+	app-arch/unzip
+	>=dev-libs/protobuf-3.6.0
+	dev-java/java-config
+	dev-python/mock
+	dev-lang/swig
+	dev-python/cython
+	|| (
+		=dev-util/bazel-0.24*
+		=dev-util/bazel-0.26*
+		=dev-util/bazel-0.27*
+	)
+	cuda? (
+		>=dev-util/nvidia-cuda-toolkit-9.1[profiler]
+	)
+	!python? ( dev-lang/python )
+	python? (
+		>=dev-python/grpcio-tools-1.22.0
+	)"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS CONTRIBUTING.md ISSUE_TEMPLATE.md README.md RELEASE.md )
+CHECKREQS_MEMORY="5G"
+CHECKREQS_DISK_BUILD="5G"
+
+get-cpu-flags() {
+	local i f=()
+	# Keep this list in sync with tensorflow/core/platform/cpu_feature_guard.cc.
+	for i in sse sse2 sse3 sse4_1 sse4_2 avx avx2 fma4; do
+		use cpu_flags_x86_${i} && f+=( -m${i/_/.} )
+	done
+	use cpu_flags_x86_fma3 && f+=( -mfma )
+	echo "${f[*]}"
+}
+
+pkg_setup() {
+	local num_pythons_enabled
+	num_pythons_enabled=0
+	count_impls(){
+		num_pythons_enabled=$((${num_pythons_enabled} + 1))
+	}
+	use python && python_foreach_impl count_impls
+
+	# 5 G to build C/C++ libs, 5G per python impl
+	CHECKREQS_DISK_BUILD="$((5 + 5 * $num_pythons_enabled))G"
+	check-reqs_pkg_setup
+}
+
+src_unpack() {
+	# Only unpack the main distfile
+	unpack "${P}.tar.gz"
+	unpack tensorflow-patches-${PVR}.tar.bz2
+	bazel_load_distfiles "${bazel_external_uris}"
+}
+
+src_prepare() {
+	export JAVA_HOME=$(java-config --jre-home) # so keepwork works
+
+	append-flags $(get-cpu-flags)
+	bazel_setup_bazelrc
+
+	eapply "${WORKDIR}"/patches/*.patch
+
+	default
+	use python && python_copy_sources
+
+	use cuda && cuda_add_sandbox
+}
+
+src_configure() {
+	export JAVA_HOME=$(java-config --jre-home) # so keepwork works
+
+	do_configure() {
+		export CC_OPT_FLAGS=" "
+		export TF_ENABLE_XLA=0
+		export TF_NEED_OPENCL_SYCL=0
+		export TF_NEED_OPENCL=0
+		export TF_NEED_COMPUTECPP=0
+		export TF_NEED_ROCM=0
+		export TF_NEED_MPI=$(usex mpi 1 0)
+		export TF_SET_ANDROID_WORKSPACE=0
+
+		if use python; then
+			python_export PYTHON_SITEDIR
+			export PYTHON_BIN_PATH="${PYTHON}"
+			export PYTHON_LIB_PATH="${PYTHON_SITEDIR}"
+		else
+			export PYTHON_BIN_PATH="$(which python)"
+			export PYTHON_LIB_PATH="$(python -c 'from distutils.sysconfig import *; print(get_python_lib())')"
+		fi
+
+		export TF_NEED_CUDA=$(usex cuda 1 0)
+		export TF_DOWNLOAD_CLANG=0
+		export TF_CUDA_CLANG=0
+		export TF_NEED_TENSORRT=0
+		if use cuda; then
+			export TF_CUDA_PATHS="${EPREFIX%/}/opt/cuda"
+			export GCC_HOST_COMPILER_PATH="$(cuda_gccdir)/$(tc-getCC)"
+			export TF_CUDA_VERSION="$(cuda_toolkit_version)"
+			export TF_CUDNN_VERSION="$(cuda_cudnn_version)"
+			einfo "Setting CUDA version: $TF_CUDA_VERSION"
+			einfo "Setting CUDNN version: $TF_CUDNN_VERSION"
+		fi
+
+		local SYSLIBS=(
+			absl_py
+			astor_archive
+			boringssl
+			com_github_googleapis_googleapis
+			com_github_googlecloudplatform_google_cloud_cpp
+			com_google_protobuf
+			com_google_protobuf_cc
+			com_googlesource_code_re2
+			curl
+			cython
+			double_conversion
+			enum34_archive
+			flatbuffers
+			gast_archive
+			gif_archive
+			grpc
+			hwloc
+			icu
+			jpeg
+			jsoncpp_git
+			keras_applications_archive
+			lmdb
+			nasm
+			nsync
+			org_sqlite
+			pasta
+			pcre
+			png_archive
+			protobuf_archive
+			six_archive
+			snappy
+			swig
+			termcolor_archive
+			wrapt
+			zlib_archive
+		)
+
+		export TF_SYSTEM_LIBS="${SYSLIBS[@]}"
+		export TF_IGNORE_MAX_BAZEL_VERSION=1
+
+		# This is not autoconf
+		./configure || die
+
+		echo 'build --config=noaws --config=nohdfs --config=noignite --config=nokafka' >> .bazelrc || die
+		echo 'build --define tensorflow_mkldnn_contraction_kernel=0' >> .bazelrc || die
+		echo 'build --incompatible_no_support_tools_in_action_inputs=false' >> .bazelrc || die
+	}
+	if use python; then
+		python_foreach_impl run_in_build_dir do_configure
+	else
+		do_configure
+	fi
+}
+
+src_compile() {
+	export JAVA_HOME=$(java-config --jre-home) # so keepwork works
+
+	if use python; then
+		python_setup
+		BUILD_DIR="${S}-${EPYTHON/./_}"
+		cd "${BUILD_DIR}"
+	fi
+
+	# fail early if any deps are missing
+	ebazel build --nobuild \
+		//tensorflow:libtensorflow_framework.so \
+		//tensorflow:libtensorflow.so \
+		//tensorflow:libtensorflow_cc.so \
+		$(usex python '//tensorflow/tools/pip_package:build_pip_package' '')
+
+	ebazel build \
+		//tensorflow:libtensorflow_framework.so \
+		//tensorflow:libtensorflow.so
+	ebazel build //tensorflow:libtensorflow_cc.so
+
+	do_compile() {
+		ebazel build //tensorflow/tools/pip_package:build_pip_package
+	}
+	BUILD_DIR="${S}"
+	cd "${BUILD_DIR}"
+	use python && python_foreach_impl run_in_build_dir do_compile
+	ebazel shutdown
+}
+
+src_install() {
+	local i j
+	export JAVA_HOME=$(java-config --jre-home) # so keepwork works
+
+	do_install() {
+		einfo "Installing ${EPYTHON} files"
+		local srcdir="${T}/src-${MULTIBUILD_VARIANT}"
+		mkdir -p "${srcdir}" || die
+		bazel-bin/tensorflow/tools/pip_package/build_pip_package --src "${srcdir}" || die
+		cd "${srcdir}" || die
+		esetup.py install
+
+		# libtensorflow_framework.so is in /usr/lib already
+		python_export PYTHON_SITEDIR PYTHON_SCRIPTDIR
+		rm -f "${D}/${PYTHON_SITEDIR}"/${PN}/lib${PN}_framework.so* || die
+		python_optimize
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir do_install
+
+		# Symlink to python-exec scripts
+		for i in "${ED}"/usr/lib/python-exec/*/*; do
+			n="${i##*/}"
+			[[ -e "${ED}/usr/bin/${n}" ]] || dosym ../lib/python-exec/python-exec2 "/usr/bin/${n}"
+		done
+
+		python_setup
+		local BUILD_DIR="${S}-${EPYTHON/./_}"
+		cd "${BUILD_DIR}" || die
+	fi
+
+	einfo "Installing headers"
+	ebazel build //tensorflow:install_headers
+	ebazel shutdown
+	insinto /usr/include/${PN}/
+	doins -r bazel-genfiles/tensorflow/include/*
+
+	einfo "Installing libs"
+	# Generate pkg-config file
+	${PN}/c/generate-pc.sh --prefix="${EPREFIX}"/usr --libdir=$(get_libdir) --version=${MY_PV} || die
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc ${PN}_cc.pc
+
+	for l in libtensorflow{,_framework,_cc}.so; do
+		dolib.so bazel-bin/tensorflow/${l}
+		dolib.so bazel-bin/tensorflow/${l}.$(ver_cut 1)
+		dolib.so bazel-bin/tensorflow/${l}.$(ver_cut 1-3)
+	done
+
+	einstalldocs
+}